Como responder automaticamente uma chamada do Skype recebida?

Question

É possível responder automaticamente a uma chamada do Skype recebida de um número ou contato específico?

Acho que isso deve funcionar com um script Python usando o Skype4py, mas como não sou programador, não tenho ideia de como fazer isso.

Alguém tem alguma sugestão?

    

Answer 1

Assumindo que o seu Skype está on-line, ou seja, você fez login e não há problemas de rede, você pode fazer o seguinte:

1. Na lista de números de telefone do skype há um buttom no parte inferior da janela do skype que lhe dá acesso às configurações. Clique sobre isso, e o menu "opções" aparece.
2. Vá para notificações e selecione "toque de chamada recebida". Agora selecione "Advanced View".
3. Na parte inferior da "visualização avançada", há uma opção para "Executar o script a seguir ", no qual você insere o caminho completo de sua roteiro.
4. Pressione aplicar.

O script

global _proc
global use_growl

tell application "System Events" to set _proc to name of processes as list
if _proc contains "GrowlHelperApp" then
    set use_growl to true
    my growlRegister()
else
    set use_growl to false
end if

if _proc contains "Skype" then
    tell application "Skype"
        set calls to send command "SEARCH ACTIVECALLS" script name "AnsweringScript"
        set callID to last word of calls
        if callID is not "CALLS" then
            set status to send command "GET CALL " & callID & " STATUS" script name "AnsweringScript"
            if last word of status is "RINGING" then
                send command "ALTER CALL " & callID & " ANSWER" script name "AnsweringScript"
                my growlNotify("SkypeAnswer", "Answering call")
                return
            else
                send command "ALTER CALL " & callID & " HANGUP" script name "AnsweringScript"
                my growlNotify("SkypeAnswer", "Hanging up")
            end if
        else
            my growlNotify("SkypeAnswer", "No call found to answer or hang up")
        end if
    end tell
else
    my growlNotify("SkypeAnswer", "Skype not detected")
end if

using terms from application "GrowlHelperApp"
    on growlRegister()
        tell application "GrowlHelperApp"
            register as application "SkypeAnswer" all notifications {"Alert"} default notifications {"Alert"} icon of application "Skype.app"
        end tell
    end growlRegister

    on growlNotify(grrTitle, grrDescription)
        if use_growl is true then
            tell application "GrowlHelperApp"
                notify with name "Alert" title grrTitle description grrDescription application name "SkypeAnswer"
            end tell
        end if
    end growlNotify
end using terms from

Referência: 1

Atenciosamente

BHM