Como renomear simultaneamente um arquivo no MS Office e excluir a versão antiga?

Question

No Microsoft Office, quando se deseja salvar um arquivo em um nome de arquivo diferente sem manter uma cópia do nome do arquivo anterior, isso exige duas etapas:

• Primeiro, Arquivo - > Salvar como ... e selecione o novo nome. Uma cópia do arquivo é feita.
• Em seguida, vá para o Windows Explorer e exclua o arquivo antigo com o nome antigo.

Eu gostaria de simplificar essas etapas "renomeando" o arquivo, do próprio Office, em uma única etapa. Como eu pude fazer isso?

Para uma versão mais divertida e enigmática, consulte Revisão 1 .

    

Answer 1

A maneira "mais fácil" de responder a isso parece estar aumentando significativamente a esta resposta .

1. Insira o seguinte código no modelo normal.dotm (encontrado em C:\Documents and Settings\user name\Application Data\Microsoft\Templates para o Windows 7 para Word)
2. Salvar normal.dotm
3. Adicione isto à barra de ferramentas quicklaunch no Word.
4. Opcional - remapeie um atalho de teclado para este
5. Opcional - assine digitalmente seu modelo (recomendado)

Observe que isso realmente move o arquivo antigo para a Lixeira, em vez de descartá-lo completamente, além de definir o novo nome de arquivo de uma maneira muito conveniente.

Option Explicit

 'To send a file to the recycle bin, we'll need to use the Win32 API
 'We'll be using the SHFileOperation function which uses a 'struct'
 'as an argument. That struct is defined here:
Private Type SHFILEOPSTRUCT
    hwnd As Long
    wFunc As Long
    pFrom As String
    pTo As String
    fFlags As Integer
    fAnyOperationsAborted As Long
    hNameMappings As Long
    lpszProgressTitle As Long
End Type

 ' function declaration:
Private Declare Function SHFileOperation Lib "shell32.dll" Alias "SHFileOperationA" (lpFileOp As SHFILEOPSTRUCT) As Long

 'there are some constants to declare too
Private Const FO_DELETE = &H3
Private Const FOF_ALLOWUNDO = &H40
Private Const FOF_NOCONFIRMATION = &H10
Private Const FOF_SILENT = &H4

Function RecycleFile(FileName As String, Optional UserConfirm As Boolean = True, Optional HideErrors As Boolean = False) As Long
     'This function takes one mandatory argument (the file to be recycled) and two
     'optional arguments: UserConfirm is used to determine if the "Are you sure..." dialog
     'should be displayed before deleting the file and HideErrors is used to determine
     'if any errors should be shown to the user

    Dim ptFileOp As SHFILEOPSTRUCT
     'We have declared FileOp as a SHFILEOPSTRUCT above, now to fill it:
    With ptFileOp
        .wFunc = FO_DELETE
        .pFrom = FileName
        .fFlags = FOF_ALLOWUNDO
        If Not UserConfirm Then .fFlags = .fFlags + FOF_NOCONFIRMATION
        If HideErrors Then .fFlags = .fFlags + FOF_SILENT
    End With
     'Note that the entire struct wasn't populated, so it would be legitimate to change it's
     'declaration above and remove the unused elements. The reason we don't do that is that the
     'struct is used in many operations, some of which may utilise those elements

     'Now invoke the function and return the long from the call as the result of this function
    RecycleFile = SHFileOperation(ptFileOp)

End Function


Sub renameAndDelete()

    ' Store original name
    Dim sOriginalName As String
    sOriginalName = ActiveDocument.FullName

    ' Save As
    Dim sFilename As String, fDialog As FileDialog, ret As Long
    Set fDialog = Application.FileDialog(msoFileDialogSaveAs)

    'set initial name so you don't have to navigate to
    fDialog.InitialFileName = sOriginalName

    ret = fDialog.Show

    If ret <> 0 Then
        sFilename = fDialog.SelectedItems(1)
    Else
        Exit Sub
    End If

    Set fDialog = Nothing

    'only do this if the file names are different...
    If (sFilename <> sOriginalName) Then
        'I love vba's pretty code
         ActiveDocument.SaveAs2 FileName:=sFilename, FileFormat:= _
            wdFormatXMLDocument, LockComments:=False, Password:="", AddToRecentFiles _
            :=True, WritePassword:="", ReadOnlyRecommended:=False, EmbedTrueTypeFonts _
            :=False, SaveNativePictureFormat:=False, SaveFormsData:=False, _
            SaveAsAOCELetter:=False, CompatibilityMode:=14

        ' Delete original (don't care about errors, I guess)
        Dim hatersGonnaHate As Integer
        hatersGonnaHate = RecycleFile(sOriginalName, False, True)

    End If

End Sub

    

Answer 2

Você não pode fazer isso com funcionalidade incorporada. Como o office declara em sua documentação

Renaming a file changes the file name of an existing file. You cannot rename a file while someone has it open in any program. The file must be closed, and if it is a shared file, it must be checked in. You can save an open file with a new name, but a copy of the file with the original name will still exist.

Parece que algo como isso poderia ser criado criando uma função personalizada "Renomear como ..." com VSTO ou VBA (como na resposta de Oliver). Você teria que programá-lo para salvar uma nova cópia e depois excluir a antiga.

    

Answer 3

Aqui está uma pequena macro VBA que eu joguei junto, que faz basicamente exatamente o que você quer:

Sub Macro1()
    ' Store original name
    Dim sOriginalName As String
    sOriginalName = ActiveDocument.FullName

    ' Save As
    Dim sFilename As String, fDialog As FileDialog, ret As Long
    Set fDialog = Application.FileDialog(msoFileDialogSaveAs)
    ret = fDialog.Show
    If ret <> 0 Then
        sFilename = fDialog.SelectedItems(1)
    Else
        Exit Sub
    End If
    Set fDialog = Nothing

    ' Don't replace the original file
    If sFilename = sOriginalName Then Exit Sub

     ActiveDocument.SaveAs2 FileName:=sFilename, FileFormat:= _
        wdFormatXMLDocument, LockComments:=False, Password:="", AddToRecentFiles _
        :=True, WritePassword:="", ReadOnlyRecommended:=False, EmbedTrueTypeFonts _
        :=False, SaveNativePictureFormat:=False, SaveFormsData:=False, _
        SaveAsAOCELetter:=False, CompatibilityMode:=14

    ' Delete original
    Kill sOriginalName
End Sub

    

Answer 4

Não, não é uma função incorporada.

Um trabalho seria salvar o arquivo com o novo nome. Em seguida, volte para Arquivo, Salvar como e exclua o arquivo antigo, o que o tornaria mais eficiente do que fechar seu documento, explorador, renomear e reabrir.

    

Answer 5

Aqui está uma pequena variação na resposta do @Travis.

Novamente, não é uma função incorporada.

1. No Word, feche o arquivo, confirmando para salvar as alterações, se necessário.
2. Ainda no Word, clique para abrir um arquivo.
3. Navegue até o arquivo, se necessário, clique com o botão direito do mouse no arquivo e renomeie-o.
4. Ainda na caixa de diálogo Abrir arquivo, abra o arquivo renomeado.
   

Esta solução:

1. Elimina a unidade longa e solitária no Windows Explorer para excluir o arquivo antigo.
2. É apenas uma viagem para a caixa de diálogo Abrir arquivo / Salvar como.
3. Conclui a operação com apenas mais alguns cliques do mouse do que apenas a operação Salvar como.
4. Também conclui a operação com apenas mais alguns cliques do mouse do que um VBA ou solução semelhante.