Existe alguma ferramenta de linha de comando que possa ser usada para editar variáveis de ambiente no Windows?

Question

Existe alguma ferramenta de linha de comando que possa ser usada para editar variáveis de ambiente no Windows?

Seria bom se essa fosse uma ferramenta inteligente, por exemplo:

• Ao adicionar um caminho para digamos que a variável PATH e esse caminho já estejam lá, ele não deve dobrar essa entrada.
• A inserção de um novo caminho para a variável PATH deve ser possível antes / depois de algum outro caminho ou em uma ordem específica (o primeiro, o sétimo, o último, etc.).
• Deve ser possível alterar apenas parte do valor da variável (no caso do PATH um determinado caminho de uma lista de todos os caminhos).

E o último, mas não o menos importante - Eu quero que minhas alterações persistam entre as sessões para que o SET esteja fora de questão ...

Existe uma ferramenta GUI muito boa para isso chamada Path Editor e eu preciso de algo assim, mas para linha de comando.

    

Answer 1

O Path Manager (pathman.exe) do Windows Server 2003 Resource Kit Tools é a correspondência mais próxima que encontrei. Já estava disponível no NT Resource Kit.

    

Answer 2

Eu não conheço nenhuma ferramenta que faça isso, mas talvez você possa usar o comando reg :

reg query "HKLM\SYSTEM\CurrentControlSet\Control\Session Manager\Environment" /v Path

para ler o caminho atual e

reg add "HKLM\SYSTEM\CurrentControlSet\Control\Session Manager\Environment" /v Path /d "newPath" /f

para escrever seu novo valor.

Você precisa de direitos de administrador para ter acesso correto à HKLM. Se isso for um problema, considere modificar a configuração do caminho específico do usuário em HKCU\Environment .

    

Answer 3

Se você precisar de uma maneira genérica de definir qualquer variável de ambiente e as alterações persistirem, setx.exe seria a ferramenta a ser usada. Não pode fazer as coisas "inteligentes" que você está pedindo, embora ...

setx.exe está incluído no Windows Vista ou posterior; Se você usa uma versão anterior do Windows, pode usar o link de download acima para obtê-lo.

    

Answer 4

Para o programa atual, há path :

Displays or sets a search path for executable files.

PATH [[drive:]path[;...][;%PATH%]
PATH ;

Type PATH ; to clear all search-path settings and direct cmd.exe to search only in the current directory.

Type PATH without parameters to display the current path. Including %PATH% in the new path setting causes the old path to be appended to the new setting.

No entanto, isso é praticamente o mesmo que set PATH .

Para variáveis de ambiente persistirem, você precisa editar o registro ou usar setx .

    

Answer 5

Acabei de descobrir a capacidade de permitir que os usuários executem a caixa de diálogo de variáveis de ambiente sem privilégios elevados.

No menu Iniciar, execute o seguinte:

rundll32 sysdm.cpl,EditEnvironmentVariables

    

Answer 6

define PATH

(conjunto de ajuda)

    

Answer 7

Eu escrevi um conjunto de scripts em lote para isso. addpath.bat adiciona elementos ao caminho, o rmpath.bat remove elementos do caminho e o lpath.bat apenas lista o caminho. Mas então eu precisei de alguns scripts de suporte, então também há o chkpath.bat.

Isso acabou não sendo trivial e exigiu o tr.exe e o cat.exe, alguns utilitários no estilo unix. A razão não é trivial: não há backticks no cmd.exe (embora você possa usar loops para isso), e nomes curtos versus nomes longos.

addpath.bat:

@echo off
setlocal
set cwd=%~dps0

goto testit

:loopy

call %cwd%chkpath "%~1"
if %errorlevel%==2 (
  set path=%path%;%~1
)

shift

:testit
if not _%1==_ goto loopy


call %cwd%lpath.bat

endlocal & set path=%path%

ChkPath.bat:

@echo off
goto START

-------------------------------------------------------
chkpath.bat

checks path for existence of the given segment.
Returns 1 if present, 2 if not present, 0 if not checked.

The matching and checking complicated by case sensitivity and "short pathnames".

created sometime in 2003 and lovingly maintained since then.


-------------------------------------------------------

:START
setlocal enabledelayedExpansion
set rc=0
set cwd=%~dps0
set curdrive=%~d0
set tr=%curdrive%\bin\tr.exe
set regexe=%windir%\system32\reg.exe


if _%1==_ goto Usage


@REM convert arg 1 to a fully-qualified, short path name,
@REM and then convert to uppercase.
set toupper=%~fs1
call :ToUpper
set tocheck=%toupper%


if not _%TEMP%==_ goto GotTemp
call :gettemp


:GotTemp
set d=%DATE:~4%
set stamp=%d:~6%%d:~3,2%%d:~0,2%%TIME::=%
set d=
set tempfile1=%TEMP%\chkpath1-%stamp%.tmp

echo %path% | %tr% ; \n  >  %tempfile1%

@REM check each element in the path for the match:
for /f  "delims=^" %%I in (%tempfile1%) do (
  if !rc!==0 (
call :CheckElt "%%I"
  )
)

if %rc%==0 set rc=2
goto END


--------------------------------------------
* checkelt
*
* check one element in the path to see if it is the same
* as the TOCHECK string. The element is first canonicalized.
*

:CheckElt
@REM remove surrounding quotes
set ERF=%1
if [x%ERF%]==[x] goto CheckEltDone
@REM convert to fully-qualified, short paths, uppercase
set TOUPPER=%~fs1%
call :ToUpper
if _%TOCHECK% == _%TOUPPER% set rc=1
:CheckEltDone
goto:EOF
--------------------------------------------


--------------------------------------------
* backtick
*
* invoke a command and return the result as a string.
* This is like backtick in csh or bash.
* To call, set variable BACKTICK to the command to be run.
* The result will be stored in the env variable of the same name.
*

:backtick
FOR /F "usebackq delims=" %%i IN ('%backtick%') DO (
  SET backtick=%%i
)
goto backtick_done
:backtick_none
  SET backtick=nothing to exec
:backtick_done
goto:EOF
--------------------------------------------


--------------------------------------------
* gettemp
*
* get the temporary directory, as stored in the registry.
* Relies on backtick.
*
* The result set TEMP.
*

:gettemp
set regkey=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders
set regvalname=Local AppData
set backtick=%regexe% query "%regkey%" /v "%regvalname%"
call :backtick
for /f "tokens=4" %%a in ("%backtick%") do (
  set temp=%%a
)
goto:EOF
--------------------------------------------



--------------------------------------------
* ToUpper
*
* Convert a string to all uppercase.
* To call, set variable TOUPPER to the thing to be converted.
* The result will be stored in the env variable of the same name.
*

:ToUpper
  FOR /F "usebackq delims=" %%I IN ('echo %toupper% ^| %tr% a-z A-Z') DO (
SET toupper=%%I
  )
goto:EOF
--------------------------------------------


--------------------------------------------
:CleanUp
  if _%tempfile1%==_ goto CleanUpDone
  if exist %tempfile1% del %tempfile1%
  :CleanUpDone
goto:EOF
--------------------------------------------


--------------------------------------------
:Usage
echo.
echo Usage: chkpath ^<path^>
echo checks if path element is included in path variable.
echo returns 1 if yes, 2 if no, 0 if not checked.
echo.
goto END
--------------------------------------------


:END
call :CleanUp

:ReallyEnd

endlocal & set errorlevel=%rc%
@REM set errorlevel=%rc%
@REM echo %errorlevel%

lpath.bat:

@echo.
@set curdrive=%~d0

@REM This form post-fixes a | at the end of each path element. Useful for debugging trailing spaces.
@REM @path | %curdrive%\cygwin\bin\sed.exe -e s/PATH=// -e 's/;/^|\n/g' -e 's/$/^|/g'

@REM This form shows bare path elements.
@REM @path | %curdrive%\cygwin\bin\sed.exe -e 's/PATH=//' -e 's/;/^\n/g'
@path | %curdrive%\utils\sed -e "s/PATH=//" | %curdrive%\utils\tr ; \n
@echo.

    

Answer 8

Você pode querer verificar o caminho da coleção gtools: link

Ele fornece um conjunto de comandos para o comando promt like

pathed /APPEND %CD% /USER

para anexar o caminho atual, por exemplo. Eu realmente não verifiquei para ser honesto, como eu estou totalmente bem com o uso de uma interface gráfica.

Outras opções são:

  /MACHINE: print machine PATH
     /USER: print user PATH
      /ADD: add variable at the head
   /APPEND: add variable at the tail
   /REMOVE: remove path / index
     /SLIM: strip duplicate vars
      /ENV: environment variable, defaults to PATH

Junto com a mesma coleção, você tem algumas boas ferramentas, suponho. Que "localiza arquivos executáveis no PATH".

 /EXTENSION: search for extension , can be a ; separated list
       /DIR: add directory , can be a ; separated list
 /RECURSIVE: search directories recursively
    /SINGLE: stop after the first find result
       /ENV: environment variable, defaults to PATH
FILE {FILE}: one or more files to find

Fonte: link

    

Answer 9

Como verificar se o diretório existe em% PATH%? no Stack Overflow tem uma descrição marcante do que dificulta a edição do Windows PATH junto com um arquivo em lote para superá-los. Descobrir como usar corretamente addpath.bat exigiu um pouco de prática, já que a estrutura de chamadas era nova para mim, mas isso funciona:

set _path=C:\new\directory\to\add\to\path
call addpath.bat _path
set _path=

e disparos repetidos não adicionarão o novo diretório se ele já estiver presente. Isso não resolve tornar as edições persistentes nas sessões.