Atalho de teclado para alternar entre planilhas no Excel

Question

O Excel 2007 tem um atalho de teclado que alterna entre planilhas?

    

Answer 1

Ctrl + PgUp para mover para a esquerda.

Ctrl + PgDn para mover para a direita.

    

Answer 2

macros VBA e atalhos de teclado personalizados para ativar a primeira ou última planilha

Se você quiser que um atalho de teclado real salte para a primeira ou a última planilha, coloque esse código em um módulo na pasta de trabalho "PESSOAL":

Sub ToFirstSheet()
    Sheets(1).Activate
End Sub

Sub ToLastSheet()
    Sheets(Sheets.Count).Activate
End Sub

Vá para a guia Desenvolvedor > Macros Navegue até essas macros (ToFirstSheet e ToLastSheet). Selecione um, clique em Opções e atribua um atalho de teclado. Faça o mesmo para o outro.

Ao salvar isso na pasta de trabalho "PESSOAL", ela estará disponível em qualquer arquivo do Excel.

Construído em atalhos de teclado para ativar as planilhas anterior ou seguinte

Para pular uma planilha para a esquerda ou para a direita, você pode usar esses atalhos de teclado padrão:

Ctrl + PgUp

Ctrl + PgDn

Macros VBA

para ativar a folha anterior ou seguinte

Veja como realizar o mesmo usando o VBA, tente isto:

Sub ToPreviousSheet()
    If ActiveSheet.Index = 1 Then
        ActiveWorkbook.Worksheets(ActiveWorkbook.Worksheets.Count).Activate
    Else
        ActiveWorkbook.Worksheets(ActiveSheet.Index - 1).Activate
    End If
End Sub

Sub ToNextSheet()
    If ActiveSheet.Index = ActiveWorkbook.Worksheets.Count Then
        ActiveWorkbook.Worksheets(1).Activate
    Else
        ActiveWorkbook.Worksheets(ActiveSheet.Index + 1).Activate
    End If
End Sub

Funções do VBA para retornar a folha anterior ou seguinte

Use esta função se você preferir obter o objeto da planilha anterior ou seguinte:

Function GetPreviousSheet(ByVal targetSheet As Worksheet) As Worksheet
    Dim targetBook As Workbook
    Set targetBook = targetSheet.Parent

    If targetSheet.Index = 1 Then
        Set GetPreviousSheet = targetBook.Worksheets(targetBook.Worksheets.Count)
    Else
        Set GetPreviousSheet = targetBook.Worksheets(targetSheet.Index - 1)
    End If
End Function

Function GetNextSheet(ByVal targetSheet As Worksheet) As Worksheet
    Dim targetBook As Workbook
    Set targetBook = targetSheet.Parent

    If targetSheet.Index = targetBook.Worksheets.Count Then
        Set GetNextSheet = targetBook.Worksheets(1)
    Else
        Set GetNextSheet = targetBook.Worksheets(targetSheet.Index + 1)
    End If
End Function

Use as funções assim:

Sub EXAMPLE()
    MsgBox "Previous Sheet:  " & GetPreviousSheet(ActiveSheet).Name
    MsgBox "Next Sheet:  " & GetNextSheet(ActiveSheet).Name
    GetNextSheet(ActiveSheet).Activate
End Sub

    

Answer 3

Você também pode usar as teclas aceleradoras para acessar a caixa de diálogo Go . Você pode então digitar algo como foo!A1 para navegar até a célula superior esquerda na planilha chamada "foo". Enquanto page up e page down são geralmente mais rápidos. Se você tiver um número grande (por exemplo, 20+) de planilhas bem nomeadas, isso poderá ser mais rápido. Ir também funciona bem se você tiver nomeado tabelas em suas planilhas.

Pressionar F5 normalmente abre a caixa de diálogo Go .