Não é possível fazer com que a ferramenta de recorte do Windows seja executada automaticamente com o AutoHotKey

Question

Estou tentando executar a ferramenta de sniping do Windows 7 quando pressiono meu botão do teclado PRINTSCREEN com o AUTOHOTKEY.

Eu não tive sucesso até agora. Aqui está o que eu tenho para o script AutoHotKey.

Eu tentei isso

PRINTSCREEN::Run, c:\windows\system32\SnippingTool.exe

e isso

PRINTSCREEN::Run, SnippingTool.exe

e isso

PRINTSCREEN::Run, SnippingTool

E todos aqueles me dão um erro que basicamente diz que ele não pode encontrar o arquivo, porém o caminho do arquivo parece estar correto, eu posso copiar colá-lo em uma janela e ele abre a ferramenta de recorte, qualquer idéia porque não vai funcionar ?

Aqui está o código completo para o meu arquivo AHK ...

;
; AutoHotkey Version: 1.x
; Language:       English
; Platform:       Win7
; Author:         Jason Davis <friendproject@>
;
; Script Function:
; Template script (you can customize this template by editing "ShellNew\Template.ahk" in your Windows folder)
;

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.


/*
PRINTSCREEN = Will run Windows 7 snipping tool
*/
PRINTSCREEN::Run, c:\windows\system32\SnippingTool.exe
return

    

Answer 1

Você está executando uma versão de 64 bits do Windows 7 por acaso?

O Windows 7 (assim como o Vista, acredito) implementa o que é chamado de Redirecionamento do WoW64 Filesystem. Se este for o caso, você vai querer apontar o AHK para o diretório Sysnative:

PrintScreen::Run, "C:\Windows\Sysnative\SnippingTool.exe"

    

Answer 2

Use

PrintScreen::Run C:\Windows\explorer.exe C:\Windows\system32\SnippingTool.exe

Isto irá chamar corretamente o executável dentro dos limites do Redirecionamento do WoW64 Filesystem

    

Answer 3

Você pode determinar se precisa chamar SnippingTool.exe a partir do Sysnative ou do windows32 com base no fato de o autohotkey estar sendo executado como um processo Wow64 ou não.

PrintScreen::LaunchSnippingTool()

; Determines if we are running a 32 bit program (autohotkey) on 64 bit Windows
IsWow64Process()
{
   hProcess := DllCall("kernel32\GetCurrentProcess")
   ret := DllCall("kernel32\IsWow64Process", "UInt", hProcess, "UInt *", bIsWOW64)
   return ret & bIsWOW64
}

; Launch snipping tool using correct path based on 64 bit or 32 bit Windows
LaunchSnippingTool()
{
    if(IsWow64Process())
    {
        Run, %windir%\Sysnative\SnippingTool.exe
    }
    else
    {
        Run, %windir%\system32\SnippingTool.exe
    }
}

Mais informações e fontes para o IsWow64Process aqui: link