Este é o VBA ou uma macro que você pode executar na sua planilha. Você deve pressionar alt + F11 para abrir o prompt do Visual Basic for Application, vá para sua pasta de trabalho e right click - insert - module e cole este código lá. Você pode então executar o módulo a partir do VBA pressionando F5 . Esta macro é denominada "teste"
Sub test()
'define variables
Dim RowNum as long, LastRow As long
'turn off screen updating
Application.ScreenUpdating = False
'start below titles and make full selection of data
RowNum = 2
LastRow = Cells.SpecialCells(xlCellTypeLastCell).Row
Range("A2", Cells(LastRow, 4)).Select
'For loop for all rows in selection with cells
For Each Row In Selection
With Cells
'if customer name matches
If Cells(RowNum, 1) = Cells(RowNum + 1, 1) Then
'and if customer year matches
If Cells(RowNum, 4) = Cells(RowNum + 1, 4) Then
'move attribute 2 up next to attribute 1 and delete empty line
Cells(RowNum + 1, 3).Copy Destination:=Cells(RowNum, 3)
Rows(RowNum + 1).EntireRow.Delete
End If
End If
End With
'increase rownum for next test
RowNum = RowNum + 1
Next Row
'turn on screen updating
Application.ScreenUpdating = True
End Sub
Isso será executado em uma planilha classificada e combinará linhas consecutivas que correspondem ao cliente e ao ano e excluirá a linha agora vazia. A planilha deve ser classificada da maneira que você a apresentou, clientes e anos em ascensão, essa macro em particular não vai olhar além das linhas consecutivas .
Editar - é totalmente possível que meu with statement seja completamente desnecessário, mas não está prejudicando ninguém ..
REVISITADO em 28/02/14
Alguém usou essa resposta em outro pergunta e quando voltei achei esse VBA pobre. Eu refiz isso -
Sub CombineRowsRevisited()
Dim c As Range
Dim i As Integer
For Each c In Range("A2", Cells(Cells.SpecialCells(xlCellTypeLastCell).Row, 1))
If c = c.Offset(1) And c.Offset(,4) = c.Offset(1,4) Then
c.Offset(,3) = c.Offset(1,3)
c.Offset(1).EntireRow.Delete
End If
Next
End Sub
Revisitado 05/04/16
Perguntado novamente Como combinar valores de várias linhas em uma única linha? Tem um módulo, mas precisa das variáveis explicando e, novamente, é muito ruim.
Sub CombineRowsRevisitedAgain()
Dim myCell As Range
Dim lastRow As Long
lastRow = Cells(Rows.Count, "A").End(xlUp).Row
For Each myCell In Range(Cells("A2"), Cells(lastRow, 1))
If (myCell = myCell.Offset(1)) And (myCell.Offset(0, 4) = myCell.Offset(1, 4)) Then
myCell.Offset(0, 3) = myCell.Offset(1, 3)
myCell.Offset(1).EntireRow.Delete
End If
Next
End Sub
No entanto, dependendo do problema, talvez seja melhor usar step -1 em um número de linha para que nada seja ignorado.
Sub CombineRowsRevisitedStep()
Dim currentRow As Long
Dim lastRow As Long
lastRow = Cells(Rows.Count, 1).End(xlUp).Row
For currentRow = lastRow To 2 Step -1
If Cells(currentRow, 1) = Cells(currentRow - 1, 1) And _
Cells(currentRow, 4) = Cells(currentRow - 1, 4) Then
Cells(currentRow - 1, 3) = Cells(currentRow, 3)
Rows(currentRow).EntireRow.Delete
End If
Next
End Sub