Defina o Internet Explorer como o navegador padrão na linha de comando

Question

É possível definir o Internet Explorer como o navegador padrão para iniciar a partir da linha de comando?

Eu tenho um aplicativo da web que é executado somente no Internet Explorer, mas se acontecer que o Firefox seja o navegador padrão, ele não funcionará. Os usuários estão em um ambiente de domínio e, embora eu tente iniciar nosso aplicativo a partir de um lote dessa maneira:

start "C:\Program Files\Internet Explorer\iexplore.exe" http://server_ip/home_page

o aplicativo não inicia a menos que eu mude o navegador manualmente.

    

Answer 1

Este comando irá definir o IE como navegador padrão:

shmgrate.exe OcinstallreinstallIE

Esta política deve impedir que as pessoas determinem o navegador padrão.

    

Answer 2

você pode tentar isso, vai funcionar

start "" "C:\Program Files\Internet Explorer\iexplore.exe" http://server_ip/home_page

o erro em seu comando foi que start espera que a primeira string citada seja o título do aplicativo, que, nesse caso, você pode deixar em branco.

para definir iexplorer.exe como o navegador padrão do sistema, você pode usar os comandos assoc e ftype , que associam extensões a tipos de arquivos e tipos de arquivos a arquivos executáveis, da seguinte forma:

assoc .html=htmlfile
ftype htmlfile="C:\Program Files\Internet Explorer\iexplore.exe" %1

%1 é o argumento aqui - essa é a URL ou o arquivo que você pode enviar para o programa como uma entrada

    

Answer 3

Windows Vista e posterior, IE 7 +

O script em lote a seguir simula clicando em Definir este programa como padrão no miniaplicativo do painel de controle Programas padrão. Testado com o Vista / 7 e o IE 7 / IE 11.

@echo off
setlocal enabledelayedexpansion

REM -- check XHTML support (IE 9+)
set xhtml=0
for /f %%G in ('"reg query "HKCR\IE.AssocFile.XHT" /ve 2>&1 | findstr /c:".XHT" "') do set xhtml=1

REM -- reset file extensions
set exts=HTM,HTML
if %xhtml% == 1 (set exts=%exts%,XHT,XHTML)

for %%G in (%exts%) do (
set ext=%%G
set ext=!ext:~0,3!
reg add "HKCU\Software\Classes\.%%G" /ve /t REG_SZ /d "IE.AssocFile.!ext!" /f >nul
)

set exts=%exts%,MHT,MHTML,URL
set acl=%temp%\acl_%random%%random%.txt

for %%G in (%exts%) do (
set key=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\.%%G\UserChoice
echo !key! [1 7 17]>"%acl%"
regini "%acl%" >nul
set ext=%%G
set ext=!ext:~0,3!
reg add "!key!" /v "Progid" /t REG_SZ /d "IE.AssocFile.!ext!" /f >nul
)
del "%acl%" 2>nul

REM -- reset MIME associations
for %%G in (message/rfc822,text/html) do (
set key=HKCU\Software\Microsoft\Windows\Shell\Associations\MIMEAssociations\%%G\UserChoice
reg add "!key!" /v "Progid" /t REG_SZ /d "IE.%%G" /f >nul
)

REM -- reset URL protocols
for %%A in (FTP,HTTP,HTTPS) do (
set key=HKCU\Software\Microsoft\Windows\Shell\Associations\UrlAssociations\%%A\UserChoice
reg add "!key!" /v "Progid" /t REG_SZ /d "IE.%%A" /f >nul
for %%B in (DefaultIcon,shell) do (
set key=HKCU\Software\Classes\%%A
reg delete "!key!\%%B" /f >nul 2>&1
reg copy "HKCR\IE.%%A\%%B" "!key!\%%B" /s /f >nul
reg add "!key!" /v "EditFlags" /t REG_DWORD /d 2 /f >nul
reg add "!key!" /v "URL Protocol" /t REG_SZ /d "" /f >nul
))

REM -- reset the start menu Internet link (Vista and earlier)
reg add "HKCU\Software\Clients\StartMenuInternet" /ve /t REG_SZ /d "IEXPLORE.EXE" /f

REM -- reset cached icons
if %xhtml% == 1 (
ie4uinit -cleariconcache
) else (
taskkill /im explorer.exe /f >nul
start explorer
)

pause
exit /b

Observações

Any web browser application can register to appear as an Internet client on the Start menu. This visibility, coupled with proper registration for an application's file and protocol types, gives an application default browser status. The default web browser is used for launching arbitrary URLs from anywhere in the system.

Note Existing [start menu link] registrations are ignored in Windows 7 and later. This registration is deprecated as of Windows 7.

_{Source: How to Register an Internet Browser or Email Client With the Windows Start Menu}

The hierarchical registry structure for file and protocol associations gives precedence to per-user defaults over machine-level defaults.

_{Source: Default Programs}

    

Answer 4

Você pode adicionar abaixo duas linhas em um arquivo bat

reg add "HKCU\Software\Microsoft\Internet Explorer\Main" /f /v "Check_Associations" /d "yes" /t REG_SZ

reg add "HKCU\Software\Microsoft\Windows\Shell\Associations\UrlAssociations\http\UserChoice" /f /v "ProgId" /d "IE.HTTP" /t REG_SZ

Depois de executar o morcego, reinicialize / faça logoff e faça log-in, uma vez que as duas linhas de comando foram criadas para alterar os valores do registro.

Detalhes adicionais podem ser encontrados aqui

(fixo) -Cant define o Internet Explorer como o navegador padrão! link

    

Answer 5

Eu não sei como configurar o navegador padrão na linha de comando, mas você pode definir e aplicá-lo ao domínio por meio da política de grupo.

Aqui está algo para você começar:

http://technet.microsoft.com/en-us/library/hh147307%28WS.10%29.aspx

    

Answer 6

Basta soltar o start para que o comando ou o arquivo em lote funcione.

"C:\Program Files\Internet Explorer\iexplore.exe" http://server_ip/home_page

    

Answer 7

Para o Windows 8 (IE 10+) é fácil o script VBS:

Dim URL 
Dim IE 
Set IE = CreateObject("internetexplorer.application")
URL = "res://ieframe.dll/defaultbrowser.htm" 
IE.Visible = True
IE.Navigate URL


 Do While IE.Busy
    WScript.Sleep 100
 Loop

IE.Document.getElementById("changeDefaultButton").Click

Ele irá iniciar a página do IE para alterar o IE como padrão e simular o clique no botão para aceitar.