Como defino uma função em partes para plotagem?

Question

Eu uso o gnuplot para plotar funções. Este é o meu script no momento:

set terminal png xffffff x222222
set output "Ausgleichszahlungen.png"
set title "Ausgleichszahlungen"
set xlabel 'F_MZ / A_MZ'
set ylabel 'Faktor F'
set xrange [0.5:1]
set yrange [0:1]
set key off
set xzeroaxis linetype -1 linewidth 0.5
set yzeroaxis linetype -1 linewidth 0.5
set xtics 0.1
set ytics 0.1
f(x) =                        0.75   * (1-x) -  317.0 /  20000
g(x) = 5.0/26 * (1-x) ** 2 + 35.0/52 * (1-x) - 2121.0 / 260000.0
h(x) = 13.0/7 * (1-x) ** 2 + 11.0/25 * (1-x)
plot f(x), g(x), h(x)

f (x), g (x) eh (x) são uma função:

-infinito < x < 0,8: f (x)

< p > 0,8 < = x < 0,93: g (x)

0,93 < = x < + infinito: h (x)

Como posso fazer isso?

    

Answer 1

Altere a última linha para

plot f(x)*(x<0.8) +  g(x) * (x>=0.8)*(x<0.93) + h(x)*(x>=0.93)

Acho isso fácil de ler, mas tem a desvantagem de que todos os f (x), g (x) eh (x) sempre serão avaliados. Você também pode usar o operador condicional ternário:

condition ? case1 : case2

avaliará em case1 se condition for true e em case2 se condition for falso. Você pode aninhar esses, então

plot x < 0.8 ? f(x) : x < 0.93 ? g(x) : h(x)

fará o trabalho para você.