Excel 2013, os dados podem ser reclassificados automaticamente?

Question

Existe uma maneira de reordenar automaticamente? Eu atualizo automaticamente as células e, dependendo dos valores recebidos, os rankings mudam. Eu estou procurando uma maneira de ter o recurso de tabela automaticamente (semelhante à formatação condicional) sem ter que clicar no botão de reordenar.

O objetivo aqui é realizar isso puramente por meio de uma função integrada do Excel2013. Eu não estou procurando uma solução que envolve células adicionais que auxiliam o tipo, como Rank (), ...

Editar

Incluo o código de uma macro que atualiza a pasta de trabalho no intervalo definido e também incluí o código em uma única planilha que deve atualizar as tabelas nessa folha em Worksheet_Calculate. Estou recebendo um erro de execução não tenho certeza do que está errado?

Public RunWhen As Double
Const frequency = 5
Const cRunWhat = "DoIt"  ' the name of the procedure to run

Sub StartTimer()
    RunWhen = Now + TimeSerial(0, 0, frequency)
    Application.OnTime RunWhen, cRunWhat, Schedule:=True
End Sub

Sub DoIt()
    Sheets("RAWDATA").Calculate
    ActiveSheet.Calculate
    StartTimer  ' Reschedule the procedure
End Sub

Sub StopTimer()
    On Error Resume Next
    Application.OnTime RunWhen, cRunWhat, Schedule:=False
End Sub

e o código que supostamente atualiza as tabelas

Private Sub Worksheet_Calculate()

With Application
    .ScreenUpdating = False
    .EnableEvents = False
    .DisplayAlerts = False
End With

ActiveSheet.ListObjects("Table2").AutoFilter.ApplyFilter
    With ActiveWorkbook.Worksheets("Strategies").ListObjects("Table2").Sort
        .Header = xlYes
        .MatchCase = False
        .Orientation = xlTopToBottom
        .SortMethod = xlPinYin
        .Apply
    End With

ActiveSheet.ListObjects("Table3").AutoFilter.ApplyFilter
    With ActiveWorkbook.Worksheets("Strategies").ListObjects("Table3").Sort
        .Header = xlYes
        .MatchCase = False
        .Orientation = xlTopToBottom
        .SortMethod = xlPinYin
        .Apply
    End With

With Application
    .ScreenUpdating = True
    .EnableEvents = True
    .DisplayAlerts = True
End With

End Sub

    

Answer 1

Eu não gosto de deixar perguntas sem resposta quando elas já foram respondidas, ele comenta. Você pode ler a história nos comentários, mas aqui está a solução final:

Private Sub Worksheet_Calculate()
    'If the active sheet is called "Strategies", then this reapplies the filter for two tables and re-sorts them

    Const wsName As String = "Strategies"

    If ActiveSheet.Name = wsName Then

        'Freeze everything and turn off events
        With Application
            .ScreenUpdating = False
            .EnableEvents = False
            .DisplayAlerts = False
        End With

        'Update Table2
        With Worksheets(wsName).ListObjects("Table2")
            .AutoFilter.ApplyFilter
            With .Sort
                .Header = xlYes
                .MatchCase = False
                .Orientation = xlTopToBottom
                .SortMethod = xlPinYin
                .Apply
            End With
        End With

        'Update Table3
        With Worksheets(wsName).ListObjects("Table3")
            .AutoFilter.ApplyFilter
            With .Sort
                .Header = xlYes
                .MatchCase = False
                .Orientation = xlTopToBottom
                .SortMethod = xlPinYin
                .Apply
            End With
        End With

        'Unfreeze things and turn events back on
        With Application
            .ScreenUpdating = True
            .EnableEvents = True
            .DisplayAlerts = True
        End With

    End If
End Sub

Você provavelmente poderia encurtar a filtragem e a classificação para apenas

    With Worksheets(wsName).ListObjects("Table2")
        .AutoFilter.ApplyFilter
        .Sort.Apply
    End With

_{Este é um wiki da comunidade porque eu não obtive a solução. Você pode editá-lo se quiser, mas tudo que fiz foi transcrever o problema encontrado nos comentários e limpar o código um pouco.}