Applescript para conectar ao dispositivo bluetooth

Question

Estou tentando criar um applescript para permitir que eu me conecte a um dispositivo bluetooth por meio de sua ID Bluetooth.

Até agora, eu consegui um applescript para ativar o bluetooth se estiver desligado. Aqui está o código:

# This is only necessary, if AppleScripts are not yet allowed to change checkboxes
tell application "System Events" to set UI elements enabled to true
# Now change the bluetooth status
  tell application "System Preferences"
    set current pane to pane id "com.apple.preferences.bluetooth"
      tell application "System Events"
        tell process "System Preferences"
        # Enabled is checkbox number 2
        if value of checkbox 2 of window "Bluetooth" is 0 then
            click checkbox 2 of window "Bluetooth"
        end if
    end tell
end tell
quit
end tell

Alguém saberia se e como é possível configurar um novo dispositivo Bluetooth e se seria possível conectar-se a um dispositivo com base no nome do dispositivo / no ID do dispositivo Bluetooth?

Eu também tentei gravar a ação no Automator, mas para a opção "configurar novo dispositivo", o Automator apenas me diz: "clique em" "botão". Obrigado

    

Answer 1

Eu consegui fazer isso graças a este link fornecido por @ mu3 nos comentários. Aqui está o Apple Script:

activate application "SystemUIServer"
tell application "System Events"
    tell process "SystemUIServer"
        -- Working CONNECT Script.  Goes through the following:
        -- Clicks on Bluetooth Menu (OSX Top Menu Bar)
        --    => Clicks on device Item
        --      => Clicks on Connect Item
        set btMenu to (menu bar item 1 of menu bar 1 whose description contains "bluetooth")
        tell btMenu
            click
            tell (menu item "Beats Solo³ de Anthonin" of menu 1)
                click
                if exists menu item "Connect" of menu 1 then
                    click menu item "Connect" of menu 1
                    return "Connecting..."
                else
                    key code 53 -- Close main BT drop down if Connect wasn't present
                    return "Connect menu was not found, are you already connected?"
                end if
            end tell
        end tell
    end tell
end tell

Tudo o que você precisa fazer é substituir "Beats Solo³ de Anthonin" pelo nome do seu dispositivo e, se o seu computador não estiver em inglês, substitua "Connect" por sua tradução no seu idioma.

Espero que isso ajude:)