Executando o Linux virtual usando qemu no windows

Question

Estou tentando usar o Qemu 1.3 para que o Windows execute o lubuntu em um dispositivo USB com o Windows 7. Após fazer o download e descompactar o Qemu no meu pen drive, se eu clicar em qemu.io.exe, obtenho

qemu-io.exe>

Como faço para iniciar meu arquivo .iso linux baixado? Parece básico, mas não está claro para mim no site da Qemu.

    

Answer 1

O manual do Qemu seria um bom lugar para começar. Isso vai ajudá-lo a descobrir o que você deve fazer a seguir, que é dizer ao qemu o que fazer e exatamente como fazer isso.

    

Answer 2

Veja como eu executo uma versão mínima do CentOS 7 em um Windows 7 Enterprise, 64 bits, sem ser membro do grupo de administradores (não administrador).

A ideia básica é:

1. Faça o download do qemu para windows e descompacte-o em qualquer lugar
2. Faça o download de uma imagem ISO da distribuição do Linux que você deseja executar
3. Crie um arquivo que será o disco rígido da sua máquina virtual
4. Executar o qemu, inicializando a partir da imagem do CD
5. Instale o sistema operacional
6. Reinicialize a máquina virtual, desta vez sem a imagem do CD

Redes e gráficos extravagantes são difíceis de acertar. Ainda lutando, na verdade ...

1. Faça o download do QEMU

Use um binário pré-compilado encontrado na página de links do QEMU . Eu usei versão 2.8.0 para isso .

Para "instalar" esta versão como não administrativa, abra um prompt de comando, emita o comando set __COMPAT_LAYER=RunAsInvoker e execute qemu-w64-setup-20170131.exe a partir desse prompt. Instale em uma pasta em que você tenha permissões de gravação, como "Meus documentos" ou algo assim.

2. Baixe uma imagem ISO do Linux

Mais uma vez, sirva-se. Eu usei a Distribuição mínima do CentOS 7 , o arquivo é chamado de CentOS-7-x86_64-Minimal-1611.iso .

3. Crie um disco rígido virtual

Eu usei um arquivo em lote para isso. Copie o seguinte em um arquivo chamado createvm.bat e ajuste as variáveis de acordo com o seu ambiente:

@echo off
rem ==================================
rem Replace with your values
rem ==================================
set "QEMUDIR=%USERPROFILE%\Documents\Warez\qemu-2.8.0-win64"

rem ==================================
rem Safety net
rem ==================================
if not exist hda.img (
    rem CREATE a virtual hard disk 
    %QEMUDIR%\qemu-img.exe create hda.img 40G
) else (
    echo file hda.img already exist. Delete or move and try again.
    goto:eof
)

4. Execute o QEMU, inicializando a partir do CD virtual

Use um lote para este, como você pode usar com frequência. Copie o seguinte em installvm.bat :

@echo off

rem ==================================
rem Replace with your values
rem ==================================
set "QEMUDIR=%USERPROFILE%\Documents\Warez\qemu-2.8.0-win64"
set "ISOFILE=CentOS-7-x86_64-Minimal-1611.iso"

rem ==================================
rem You can add a w suffix to this if 
rem you don't want a console
rem ==================================
set "QEMUBIN=qemu-system-x86_64.exe"

rem ==================================
rem Run the virtual machine
rem ==================================
start "QEMU" %QEMUDIR%\%QEMUBIN% -drive file=hda.img,index=0,media=disk,format=raw -cdrom %ISOFILE% -m 2G -L Bios -usbdevice mouse -usbdevice keyboard -boot menu=on -rtc base=localtime,clock=host -parallel none -serial none -name centos -no-acpi -no-hpet -no-reboot 

5. Instalar o sistema operacional

Eu tive problemas com o instalador da GUI. Quando solicitado a instalar o CentOS, pressione a tecla TAB e substitua a palavra quiet no final dessa linha pela palavra text .

Siga as instruções de instalação na tela. Quando a instalação estiver concluída, a máquina virtual será encerrada. Pode demorar um pouco, especialmente quando é executado como um usuário não administrador.

6. Execute sua imagem do Linux no QEMU

Esta etapa é o que você fará várias vezes para executar a VM sempre que precisar. Copie o seguinte em runvm.bat :

@echo off

rem ==================================
rem Replace with your values
rem ==================================
set "QEMUDIR=%USERPROFILE%\Documents\Warez\qemu-2.8.0-win64"

rem ==================================
rem You can add a w suffix to this if 
rem you don't want a console
rem ==================================
set "QEMUBIN=qemu-system-x86_64.exe"

rem ==================================
rem Run the virtual machine
rem ==================================
start "QEMU" %QEMUDIR%\%QEMUBIN% -drive file=hda.img,index=0,media=disk,format=raw -m 2G -L Bios -usbdevice mouse -usbdevice keyboard -boot menu=on -rtc base=localtime,clock=host -parallel none -serial none -name centos -no-acpi -no-hpet -no-reboot -device e1000,netdev=user.0 -netdev user,id=user.0,hostfwd=tcp::2222-:22

Eu adicionei um portforward local: se você ssh / putty para localhost: 2222, você alcançará o daemon SSH da sua VM. Tenha em atenção que firewalld ou iptables pode bloquear o tráfego, dependendo da forma como instalou o Linux.