Crie estilos de título alternativos no Word

Question

Gostaria de estilizar um documento do Word com títulos que tenham uma borda ao redor deles, mas não para toda a largura da página.

Algo parecido com isto:

Otruqueéque,empáginasímpares,eugostariaqueocabeçalhofossealinhadoàdireitaenãoàesquerda.

Claro que eu poderia ter dois estilos, alinhado à esquerda e alinhado à direita ... mas eu teria que ter cuidado com a página em que estou, e teria que mudar todos os estilos para quando eu adicionasse conteúdo que mudasse o conteúdo para outra página.

Existe uma maneira que me permita definir estilos dependendo da página? É fácil de fazer com cabeçalhos, tenho certeza que há um jeito de conteúdo.

    

Answer 1

Não conheço nenhum recurso que você possa usar para definir os cabeçalhos que você precisa, a opção alternativa pode ser uma macro.

O código abaixo passa por todos os parágrafos de um documento e, para cada estilo de título (o nível de contorno é maior ou igual a 1), ele define alinhamentos e bordas verticais de acordo com o número da página.

Sub alignHeaders()
    Dim i As Integer
    Dim p As Paragraph
    Dim IndentAmount As Single

    IndentAmount = CentimetersToPoints(10) 

    Application.ScreenUpdating = False

    For Each p In ActiveDocument.Paragraphs
        With p
            If .OutlineLevel <> wdOutlineLevelBodyText Then
                If .Range.Information(wdActiveEndAdjustedPageNumber) Mod 2 = 1 Then
                    With .Range.ParagraphFormat
                        .LeftIndent = 0
                        .RightIndent = IndentAmount
                        .Borders(wdBorderLeft).LineStyle = wdLineStyleNone
                        .Borders(wdBorderRight).LineStyle = wdLineStyleSingle
                    End With
                Else
                    With .Range.ParagraphFormat
                        .RightIndent = 0
                        .LeftIndent = IndentAmount
                        .Borders(wdBorderLeft).LineStyle = wdLineStyleSingle
                        .Borders(wdBorderRight).LineStyle = wdLineStyleNone
                    End With
                End If
            End If
        End With
    Next p

    Application.ScreenUpdating = True
End Sub  

Execução da macro:

• você pode colocá-lo
  • no seu normal.dotm
  • nos documentos que você deseja ter esta formatação
  • você pode criar um arquivo de modelo no qual define os estilos de cabeçalho e também coloca essa macro
• você pode atribuir uma tecla de atalho para a macro executá-la quando achar necessário
• você também pode definir a macro para ser executada automaticamente antes de imprimir / salvar, a orientação útil é aqui (aviso: se você definir sua macro desta forma e ela estiver localizada no normal.dotm, ela formatará todos os arquivos salvos / impressos!)

Nota adicional: essa macro agora altera a formatação de todos os parágrafos em que o nível da estrutura de tópicos não está em branco, dependendo dos seus objetivos, você pode querer alterá-lo. Marcar nomes de estilo em vez de níveis de estrutura de tópicos (por exemplo, If Left(.Style,7)="Heading" ) seria uma solução óbvia, mas isso não funcionaria em outros idiomas, pois os nomes de estilo dependem do idioma.