Habilita / desabilita a configuração “Mostrar arquivos ocultos” na linha de comando

Question

No Windows Explorer, a configuração Mostrar arquivos, pastas e unidades ocultas pode ser ativada e desativada em Organise > Folder and search options > View .

Existe outra maneira mais rápida de ativar / desativar essa configuração? Algo por meio da linha de comando seria ideal, mas estou aberto a todas as sugestões mais rápidas ou menos complicadas.

    

Answer 1

Essas configurações estão no registro nessa chave:

HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced

Para mostrar itens ocultos, defina Hidden para 1 (para ocultá-los, defina-o como 2). Para mostrar itens do sistema / super-ocultos, defina ShowSuperHidden para 1 (0 para ocultar). Como estamos mexendo no Registro diretamente, o Explorer precisa ser reiniciado.

Para realizar tudo isso e permitir a visualização de tudo, você pode usar esses comandos em lote:

reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced /v Hidden /t REG_DWORD /d 1 /f
reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced /v ShowSuperHidden /t REG_DWORD /d 1 /f
powershell -c gps 'explorer' ^| stop-process

Se você preferir evitar o PowerShell, isso também deve funcionar para eliminar o Explorer:

taskkill /im explorer.exe /f

Se o Explorer não reiniciar automaticamente seu sistema, basta executar explorer para recuperar sua barra de tarefas.

    

Answer 2

Eu decidi pegar as chaves e os comandos que Ben forneceu e gravar um único arquivo de lote que ativa ou desativa os valores de Hidden e ShowSuperHidden .

Alternando arquivos ocultos / ocultos com um arquivo em lote

Você pode baixar o ToggleHidden.bat aqui , mas se preferir copiar o script em um arquivo .bat ou .cmd , aqui está o código fonte:

@echo off
REG QUERY "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v "Hidden" | Find "0x0"
If %ERRORLEVEL% == 0 goto show
IF %ERRORLEVEL% == 1 goto hide
goto :error

:show
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v Hidden /t REG_DWORD /f /d 1 > NUL
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v ShowSuperHidden /t REG_DWORD /f /d 1
goto restart

:hide
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v Hidden /t REG_DWORD /f /d 0 > NUl
REG ADD "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v ShowSuperHidden /t REG_DWORD /f /d 0
goto restart

:error
echo There was an error! Check the script.
pause
goto :eof

:restart
taskkill /f /im explorer.exe
start explorer

Um detalhamento do que o script faz: ele consulta os dados do valor Hidden ; se estiver desativado, ele alterna isso e ShowSuperHidden on. Se ele já estiver ativado, ele alterna isso e ShowSuperHidden off. Eu decidi projetar o script dessa forma porque é raro que eu pessoalmente precise ver arquivos ocultos sem também ver os arquivos do sistema, mas você pode mudar esse comportamento se preferir. ¹

Após ativar ou desativar esses valores do registro, o script mata e reinicia o processo do explorador do Windows Explorer. Se, por algum motivo, o valor de Hidden não puder ser determinado pelo comando query , o script quebrará e exibirá um erro antes de sair.

Mapeando o arquivo de lote para uma tecla de atalho

Para satisfazer meus critérios para máxima conveniência, coloquei o arquivo ToggleHidden.bat recém-criado em algum lugar no meu computador e usei AutoHotKey para mapear um combinação de teclas de atalho para executá-lo. Eu fiz isso adicionando o seguinte ao meu script AHK existente:

Ctrl & H::
Run PATH\TO\FILE
Return

Eu usei o AutoHotKey aqui porque eu já o usei para propósitos similares e achei o método mais útil de atribuir teclas de atalho para executar meus programas, mas se você preferir não ter que instalar o AHK para o propósito desta etapa, você pode também use este método nativo do Windows para atribuir hotkeys a um programa .

Agora eu posso usar a combinação de teclas de atalho Ctrl + H para ocultar e rapidamente mostrar ou ocultar arquivos ocultos / do sistema à minha conveniência ... e funciona lindamente , se eu mesmo disser isso.

¹ Se você planeja seguir esse caminho, é importante notar que, no ecossistema do Windows, arquivos / pastas super-ocultos agem como um subconjunto de arquivos / pastas ocultos.

O que isso significa quando se trata desses dois valores de registro é que você pode ativar o valor Hidden sem ativar ShowSuperHidden , mas não é possível ativar ShowSuperHidden sem ativar Hidden ; fazer isso mostrará apenas itens normais, porque o Windows considera itens ocultos um tipo de item oculto e, se itens ocultos estiverem ocultos, os itens serão ocultados. Para simplificar: se você planeja ativar o ShowSuperHidden , é necessário ativar o Hidden com ele.

    

Answer 3

A opção mostrar pasta oculta é especificamente algo que faz parte do Explorer.

Embora na linha de comando, você possa usar os comandos attrib ou dir /ah para visualizar arquivos ocultos, você não pode controlar a configuração oculta a partir da linha de comando, a menos que você passe primeiro por algum tamanho. Essencialmente, essa configuração é armazenada no registro e você pode modificar o registro a partir da linha de comando. Mas será muito mais complicado seguir esse caminho do que mudar rapidamente a configuração no explorador.

Se isso é algo que você vai fazer com freqüência, encontrar a configuração no registro e armazená-lo em um arquivo .reg seria mais rápido, porque você pode clicar duas vezes nos dois arquivos .reg para ativá-lo e desativá-lo. / p>

Infelizmente, não sei onde no registro está localizado. Eu só sei que é na colmeia HKCU, mas não exatamente onde.

Se você atualizar para o Windows 10, essa configuração poderá ser encontrada diretamente na guia de exibição.