excel - gera um nome de usuário a partir de um campo de nome completo

Question

Estou tentando gerar um nome de usuário usando um campo de nome único no Excel que tem o nome e sobrenome da pessoa. Estou aberto para o que o nome de usuário seria, desde que seja intuitivo para o usuário. Os campos de nome podem ser complicados, pois os dados se parecem com isso:

Albert Abongo (2 names)
Stephen Michael Essuah Ackah (4 names)
Alhaji Iddrisu Abdul-KArim (3 names)

Acho que meus nomes de usuário ideais para essas pessoas seriam

aabongo
sackah
aabdul-karim

    

Answer 1

Tente usar o seguinte (com os dados de entrada em A1):

=LOWER(LEFT(A1,1)&TRIM(RIGHT(SUBSTITUTE(A1," ",REPT(" ",LEN(A1))),LEN(A1))))

• LOWER : torna toda a saída em minúsculas
• LEFT(A1,1) : puxa os dados, começando da esquerda, por 1 caractere.
• & liga as duas partes juntas
• TRIM(RIGHT(SUBSTITUTE(A1," ",REPT(" ",LEN(A1))),(LEN(A1)))
  
  • a função SUBSTITUTE(A1," ",REPT(" ",LEN(A1))) conta o tamanho da string original e coloca o mesmo número de espaços em que cada espaço existe.
  • , em seguida, o (RIGHT(text,LEN(A1)) obtém, começando da direita, o tamanho da string original
    
  • TRIM remove os espaços iniciais

Answer 2

Para adicionar uma resposta inteligente do @CameronAziz, se você quiser evitar nomes de usuário duplicados, adicione outra coluna à direita desses nomes de usuário (na coluna B deste exemplo) e preencha esta fórmula:

=B1&IF(COUNTIF($B$1:B1,B1)>1,COUNTIF($B$1:B1,B1),"")

Isso adicionará um número à direita do nome de usuário, se for uma duplicata de nomes de usuários anteriores.