É possível de alguma forma esconder Growl e Herald quando o VLC roda em tela cheia?

Question

É irritante quando, ao assistir filmes, recebo notificações de grunhidos ou notificações de e-mail com o Herald. Eu pensei que uma maneira de resolver isso é definir o 'z-index' do VLC mais alto, do que as caixas de notificação de Growl e Herald. Ou talvez eu possa adicionar hook ao VLC indo fullscreen / windowed, por isso vai desativar tanto Growl e Herald para esse tempo. Algum conselho?

Se alguém estiver interessado, eu escrevi um pequeno aplicativo há algum tempo e decidi postar Aqui. É um wrapper em torno de qualquer player (o padrão é o VLC, o ajuste do player é feito largando o player no app). Quando você abre o moveie com ele, ele sai GrowlHelperApp e HeraldAgent (note que não será possível interagir com Mail.app usando mouse, e ambos os agentes serão lançados de volta quando o player sair). Além disso, se o filme for aberto com fn pressionado, o volume e o brilho serão convertidos para 85% (e transformados novamente quando o player for encerrado).

    

Answer 1

Abra o Editor AppleScript, salve como aplicativo, ao salvar marque a caixa "Fique Aberto". Use este novo aplicativo applescript para iniciar o aplicativo VLC.

Descrição: Ele iniciará o VLC, desativará as notificações de grunhido, verificará a cada 2s para ver se o VLC foi encerrado, se estiver, ele ativará novamente as notificações e, em seguida, encerrará. Como bônus, ele usará notificações de rastreamento para notificá-lo quando as notificações de grunhido forem ativadas ou desativadas. Sim, porque essa é a maneira legal de fazer isso.

Não familiarizado com o Herald, mas isso lhe dará um começo. Basta verificar para ver o processo de background do Herald e modificar o script de acordo… ou sair / reiniciar o processo de “Mail”.

global Growl_was_Loaded
global VLC_is_Loaded

on open mediaFiles
    launchThis(mediaFiles)
    idle
end open

on run
    launchThis(null)
    idle
end run

on idle
    set x to isAppLoaded("VLC")
    if x and not VLC_is_Loaded then
        launchVLC()
    else if VLC_is_Loaded and not x then
        set VLC_is_Loaded to false
        if Growl_was_Loaded then
            tell application "GrowlHelperApp" to launch
            growl_notify("Growl notifications: ON")
        end if
        tell me to quit
    end if
    return 2 -- wait 2 seconds    
end idle

on launchThis(mFiles)
    set Growl_was_Loaded to isAppLoaded("GrowlHelperApp")
    set VLC_is_Loaded to isAppLoaded("VLC")
    launchVLC(mFiles)
end launchThis

on launchVLC(mf)
    if mf is null then
        tell application "VLC" to launch
    else
        tell application "VLC" to open file mf
    end if

    if Growl_was_Loaded then
        growl_notify("Growl notifications: OFF")
        delay 1
        tell application "GrowlHelperApp" to quit
    end if
    set VLC_is_Loaded to true
    tell application "VLC" to activate
end launchVLC

on isAppLoaded(app_name)
    tell application "System Events"
        set app_list to every application process whose name is app_name
        if the (count of app_list) > 0 then
            set x to true
        else
            set x to false
        end if
    end tell
    return x
 end isAppLoaded

 on growl_notify(msg)
    tell application "GrowlHelperApp"
        set the allNotificationsList to {"Growl Toggler"}
        register as application "Growl Toggler" all notifications allNotificationsList default notifications allNotificationsList
        notify with name "Growl Toggler" title msg description "" application name "Growl Toggler" icon of application "Automator"
    end tell
end growl_notify

    

Answer 2

Execute o VLC a partir de um script que mate o Growl, o Hardware Growler and Herald, inicie o VLC e reinicie as outras tarefas quando o VLC terminar.
Outra maneira é escrevê-lo para rodar continuamente, testando a lista de processos para o VLC, e matando / retomando o Growl, etc., quando o VLC é iniciado ou encerrado.

    

Answer 3

Estas notificações visuais ou notificações de áudio ou ambas? Se for apenas visual, você poderá ocultá-los abrindo o menu de opções enquanto estiver no modo de tela inteira (seja qual for o equivalente de um clique direito para o OSX). Em seguida, passe o mouse sobre o vídeo e selecione a opção "Sempre visível".