Como ampliar e reduzir um atalho de teclado no MS Word 2013?

Question

Eu quero evitar usar o mouse, touchpad ou mover o cursor para o canto inferior direito "régua", mas eu não consegui encontrar um atalho de teclado para Zoom in / out de uma maneira Crecendo e decrégecendo. O único que encontrei é o "Zoom100", mas não é isso que estou procurando.

Existe uma maneira de fazer isso com uma macro do MS ou usando o autohotkey?

    

Answer 1

AFAIK não há atalhos de teclado especificamente para zoom.

Em vez disso, crie essas duas novas rotinas de VBA (macros):

Sub MyZoomIn()
  Dim iZoom As Long
  iZoom = ActiveWindow.View.Zoom
  iZoom = iZoom + 5
  ActiveWindow.View.Zoom = iZoom
End Sub

Sub MyZoomOut()
  Dim iZoom As Long
  iZoom = ActiveWindow.View.Zoom
  iZoom = iZoom - 5
  ActiveWindow.View.Zoom = iZoom
End Sub

Origem

Em seguida, atribua atalhos de teclado a eles:

1. Clique na guia Arquivo .

2. Clique em Opções .

3. Clique em Personalizar Faixa de Opções e, em seguida, clique em Personalizar .

4. Na caixa Salvar alterações em, clique no nome ou modelo do documento atual no qual deseja salvar as alterações de atalho de teclado.

5. Na caixa Categorias , clique na categoria que contém o comando ou outro item que você deseja atribuir a um atalho de teclado ou remover um atalho de teclado.

6. Na caixa Comandos , clique no nome do comando ou outro item para o qual deseja atribuir um atalho de teclado ou remover um atalho de teclado.

   Quaisquer atalhos de teclado atribuídos atualmente aparecem na caixa de chaves atuais.

7. Atribuir um atalho de teclado:

   a. Inicie os atalhos de teclado com a tecla CTRL ou uma tecla de função.

   b. Na caixa Pressione nova tecla de atalho , pressione a combinação de teclas que você deseja atribuir. Por exemplo, pressione CTRL e a tecla que você deseja usar.

   c. Veja em Atualmente atribuído para ver se a combinação de chaves já está atribuída a um comando ou outro item. Em caso afirmativo, selecione uma combinação diferente.

   d. Clique em Atribuir .

Origem

    

Answer 2

Eu levaria a resposta do TECHIE007 um passo adiante, adicionando o seguinte código a um módulo em Normal.dotm:

Const FineZoom As Double = 5
Const CoarseZoom As Double = 25
Const MaxZoom As Double = 500
Const MinZoom As Double = 10

Sub ZoomInFine()
    With ActiveWindow.View
        If .Zoom <= (MaxZoom - FineZoom) Then .Zoom = .Zoom + FineZoom
    End With
End Sub

Sub ZoomOutFine()
    With ActiveWindow.View
        If .Zoom >= (MinZoom + FineZoom) Then .Zoom = .Zoom - FineZoom
    End With
End Sub

Sub ZoomInCoarse()
    With ActiveWindow.View
        If .Zoom <= (MaxZoom - CoarseZoom) Then .Zoom = .Zoom + CoarseZoom
    End With
End Sub

Sub ZoomOutCoarse()
    With ActiveWindow.View
        If .Zoom >= (MinZoom + CoarseZoom) Then .Zoom = .Zoom - CoarseZoom
    End With
End Sub

Para fazer isso, abra um documento em branco no Word e, em seguida:

1. Abra o Editor do VBA pressionando Alt + F11
2. Localize "Normal" no Explorador de Projetos, clique com o botão direito do mouse e selecione "Inserir" e "Módulo"

Copie e cole o código acima no módulo de código em branco recém-criado.

Salve o código do VBA ( Ctrl + S ) e feche o Editor do VBA

Usando as instruções do TECHIE007, eu então ligaria:

• ZoomInCoarse para Ctrl + Deslocamento + Numpad +
• ZoomOutCoarse para Ctrl + Deslocamento + Numpad -
• ZoomInFine para Ctrl + Alt + Deslocamento + Numpad +
• ZoomOutFine para Ctrl + Alt + Deslocamento + Numpad -

Esta forma do código permite uma taxa ajustável de zoom, com detecção automática de limites de zoom para evitar erros de tempo de execução do VBA. Se as taxas de zoom finas e / ou grosseiras, ou os limites de zoom, não forem do agrado de uma pessoa, elas podem ser prontamente alteradas.

O comportamento pode ser ainda mais personalizado, por exemplo, adicionando macros que definem níveis favoritos de zoom e atalhos de ligação.