gVim para Windows: Como escapar corretamente nomes de arquivos que serão usados com o! start?

Question

Eu tenho este trecho de código no meu .vimrc para fazer com que arquivos de diferentes tipos sejam abertos em diferentes instâncias do gVim.

function GetSvrName(ext)
    if !exists('s:ext2srv')
        let s:ext2srv = [
                    \['PHP', ['php', 'phtml']],
                    \['JS', ['js']],
                    \['CSS', ['css']],
                    \['HTML', ['htm', 'html', 'dwt', 'lbi']],
                    \['PY', ['py']],
                    \['TXT', ['txt', 'text', 'md', 'mkd']],
                    \['C', ['c', 'cpp', 'h', 'hpp']],
                    \['LOG', ['log']],
                    \['INI', ['ini', 'conf']],
                    \['BAT', ['bat', 'sh']],
                    \]
    endif
    for srv in s:ext2srv 
        for extname in srv[1]
            if a:ext == extname
                return srv[0]
                " break
            endif
        endfor
    endfor
    return 'GVIM'
endfunction

function VimDispatch()
    if &diff || !argc()
        return 0
    endif
    let l:argv = argv()
    for a in l:argv
        let l:sp = expand('/')
        let l:lastsp = strridx(a, l:sp)
        let l:file = strpart(a, l:lastsp + 1)
        let l:lastdot = strridx(l:file, '.')
        let l:ext = strpart(l:file, l:lastdot + 1)
        let l:srvname = GetSvrName(l:ext)
        exe 'silent !start gvim --servername ' . l:srvname . ' --remote-tab-silent "' . a . '"'
        call remote_foreground(l:srvname)
    endfor
    exit
endfunction

call VimDispatch()

Mas tem alguns problemas. Uma é que alguns arquivos não podem mais ser abertos. Por exemplo, quando abro um arquivo cujo nome contém a string ~! , aparece uma caixa de mensagem:

Error detected while processing function VimDispatch:
line   12:
E34: No previous command

Ou, se o nome do arquivo contiver @# :

Error detected while processing function VimDispatch:
line   12:
E194: No alternate file name to substitute for '#': silent !start gvim --servername TXT --remote-tab-silent 
"D:\@#.txt"

E o arquivo não está aberto.

Então, como resolvo esse problema para que meu código funcione com esses nomes de arquivos?

    

Answer 1

Isso é causado por suas citações simplistas "role-seu-próprio". Você está procurando pelo comando shellescape() ; para :! , você precisa passar 1 para o argumento {special} adicional, assim:

exe 'silent !start gvim --servername ' . l:srvname . ' --remote-tab-silent ' . shellescape(a, 1)