Defina o valor de uma coluna por outra coluna no Excel

Question

Isto parece que deveria ser tão simples! Preciso definir a coluna B pela coluna A Se a coluna A for igual a qualquer valor no array "taco, hamburguer, espaguete" a coluna B deverá ser "food", se a coluna A for igual a qualquer valor no outro array "dress, shoes, belt" coluna B deverá ler " vestuário "- mas que fórmula posso usar?

OBRIGADO!

    

Answer 1

Não sei bem como definir um array definido dentro dessa fórmula , mas isso funcionará se você alterar o K1:K3 para um intervalo que contenha os itens "food"

=IF(ISERROR(MATCH(A1,K1:K3,0))=FALSE,"Food","")

Se você precisar fazer várias vezes, basta substituir o% final"" por uma nova série dessa verificação do valor em uma lista diferente de vestuário . Assim:

=IF(ISERROR(MATCH(A1,K1:K3,0))=FALSE,"Food",IF(ISERROR(MATCH(A1,L1:L3,0))=FALSE,"Clothing",""))

EDITAR

duh, você pode definir o array com chaves -

=IF(ISERROR(MATCH(A1,{"taco","burger","spaghetti"},0))=FALSE,"Food",IF(ISERROR(MATCH(A1,{"dress","shoes","belt"},0))=FALSE,"Clothing",""))

    

Answer 2

Você poderia ir com a resposta de Raystafarian se não fosse mudar seus grupos para "Comida" ou "Vestuário".

Eu recomendaria a configuração de uma tabela em outra planilha para definir seus grupos e usar uma pesquisa para traduzir. Vou pular a tabela para essa resposta, porque não é necessário.

Portanto, supondo que A1 seja a célula com "taco" ou outro valor, e as colunas A e B on Sheet2 sejam sua tabela de consulta com "taco", "shoes", etc. na coluna A e Food e Clothing na coluna B , depois coloque a seguinte fórmula onde quiser que a avaliação de A1 apareça:

=IFERROR(VLOOKUP(A1,Sheet2!A:B,2,FALSE),"")

A função VLOOKUP procura A1 na referência Sheet2!A:B e retorna a coluna 2 dessa referência. O FALSE diz para encontrar uma correspondência exata, em vez de assumir que a lista está em ordem e que uma correspondência aproximada é boa o suficiente.

A função IFERROR é apenas para capturar valores que você não colocou na tabela de consulta. Se você quiser que algo mais aconteça, altere "" .

Sheet2 deve ser assim:

   A         B
1  taco      Food
2  burger    Food
3  spaghetti Food
4  shoes     Clothing
5  dress     Clothing
6  belt      Clothing