Desktopping remoto - 1 controle de computador 30

Question

Existe uma solução de desktop remota que permitirá que um computador controle 30? Eu tenho 30 computadores de alunos em um laboratório de informática, todos exibindo a mesma página da web. Quero que o professor possa clicar no botão de login e inserir suas credenciais uma vez, em vez de precisar ir a cada computador e inseri-lo 30 vezes.

Qualquer sugestão seria útil.

    

Answer 1

Eu mostrarei a você como eu faria: (eu tenho um pequeno script autologin para meu roteador que eu usei aqui)

Instale o AutoHotkey em todos os computadores.

No computador do professor, crie um arquivo na área de trabalho chamado autologin.ahk :

mysite=http://192.168.178.1/logincheck.lua  ; the login site
myexpected=/home/home.lua                   ; part of the url after login
myuser=username                             ; username
mypass=password                             ; password

oIE:=ComObjCreate("InternetExplorer.Application")
oIE.Visible:=True
oIE.top:=oIE.left:=0, oIE.width:=A_ScreenWidth, oIE.height:=A_ScreenHeight
oIE.Navigate(mysite)
While oIE.readyState!=4 || oIE.document.readyState!="complete" || oIE.busy
   Sleep 50
SoundBeep

oForm:=oIE.document.getElementById("uiMainForm")    ; change this
oForm.elements.item("username").value:=myuser       ; change this
oForm.elements.item("uiPass").value:=mypass         ; change this
oForm.elements.item("uiSubmitLogin").Click()        ; change this
While oIE.readyState!=4 || oIE.document.readyState!="complete" || oIE.busy
   Sleep 50
SoundBeep

url:=oIE.LocationUrl
StringGetPos, pos, url, %myexpected%
if pos=-1
Loop
{
  Getkeystate, state, SPACE, P
  if state=D
    Break
  SoundBeep, 750, 500
  Sleep 50
}

Você precisa ajustar a variável de formulário do seu site. Quando o login falhar, ele apitará e continuará emitindo bips até que você pressione Espaço . Você pode testar esse script no computador do professor.

Agora crie um checker.ahk :

script=\teachers_computer\shared_folder\autologin.ahk
loop
{
  IfExist, %script%
  {
    run %script%
    sleep, 60000  ; 60 seconds
  }
  sleep 10000 ; 10 seconds
}

Execute isso no login dos computadores dos alunos. Ele verificará uma pasta compartilhada no computador do professor a cada 10 segundos se houver um autologin.ahk . Se houver, será executado e aguardará 5 minutos. (tempo suficiente para o professor remover o arquivo novamente.)

O professor pode mover o autologin.ahk de sua área de trabalho para a pasta compartilhada e aguardar até que todos os computadores estejam conectados (isso deve ocorrer em 20 segundos). Em seguida, ele pode mover o arquivo de volta para a área de trabalho para que ele não esteja mais disponível para os alunos. Quando alguns computadores continuam apitando, ele precisa ir até eles e ver porque o login não funcionou.

Não é necessário dizer que o autohotkey.ahk original precisa ser mantido seguro (o computador do professor é seguro) e o arquivo é brevemente exposto quando é descartado na pasta compartilhada ( mas diretamente removido depois pelo professor). Como isso é feito antes dos alunos chegarem atrás de seus computadores, isso não deve ser um problema.