Itens Desmarcados da barra de tarefas reaparecem após a reinicialização no Windows 10 [duplicado]

Question

Eu só precisava ter meu laptop recriado e estou configurando tudo de novo. Alguns itens foram fixados na minha barra de tarefas a partir da imagem e, quando os soltei, eles retornaram após a reinicialização. Tenho visto muitos comentários sobre a limpeza de% AppData% \ Microsoft \ Internet Explorer \ Início Rápido \ Usuário Fixado \ TaskBar e removendo HKEY_CURRENT_USER \ Software \ Microsoft \ Windows \ CurrentVersion \ Explorer \ Taskband. Também notas sobre c: \ Users \ Public \ CompanyProfile (que não existe para mim). Nenhum desses truques funcionou. Eu até criei novos usuários e estou vendo o mesmo problema nessa conta. Outro sintoma que eu tenho é que quando eu padrão meu navegador para o Firefox, ele redefine para o IE após a reinicialização. Eu verifiquei e não consigo ver nenhuma política de grupo que esteja conduzindo esse comportamento. Eu estou sem ideias.

Programas instalados para colar e itens que eu coloco no meu desktop sobrevivem a uma reinicialização. Ao olhar em volta eu tentei um programa em lote para ajudar e notei que se eu executar esses comandos no DOS:

taskkill /f /im explorer.exe
start explorer.exe

Ele redefine a barra de tarefas e as associações de arquivos.

    

Answer 1

Eu não tenho uma boa resposta para uma correção permanente. No entanto, eu consegui mascarar o problema. Acabei criando uma tarefa para executar quando efetuo login. Essa tarefa executa o script abaixo e desativa os itens da barra de tarefas.

Option Explicit

Dim objFSO, objShell, objFile, objFolder, objFolderItem, colVerbs, objShellApp, objVerb
Dim strFileNameAndPath

Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objShell = CreateObject("WScript.Shell")
Set objShellApp = CreateObject("Shell.Application")

' ***********************************************
' Unpin Internet Explorer
' ***********************************************
strFileNameAndPath = objShell.ExpandEnvironmentStrings("%APPDATA%") & _
 "\Microsoft\Internet Explorer\Quick Launch\User Pinned\Taskbar\Internet Explorer.lnk"

 ' Verify the files exists.  If not, we are got and don't need to do Anything
If objFSO.FileExists(strFileNameAndPath) Then
    set objFile = objFSO.GetFile(strFileNameAndPath)
    Set objFolder = objShellApp.Namespace(objFile.ParentFolder & "\")
    Set objFolderItem = objFolder.ParseName(objFile.Name)
    Set colVerbs = objFolderItem.Verbs
    For Each objVerb In colVerbs
        If LCase(Replace(objVerb.name, "&", "")) = "unpin from taskbar" Then objVerb.DoIt
    Next
End If

' ***********************************************
' Unpin Windows File Explorer
' ***********************************************
Set objFolder = objShellApp.Namespace("C:\ProgramData\Microsoft\Windows\Start Menu Places")

For each objFolderItem in objFolder.Items
    If InStr(1, objFolderItem.Name, "Explorer", vbTextCompare) > 0 Then
        objFolderItem.InvokeVerb("taskbarunpin")
    End If
Next

Set objVerb = Nothing
Set colVerbs = Nothing
set objFile = Nothing
Set objFolder = Nothing
Set objFolderItem = Nothing
Set objFSO = Nothing
Set objShell = Nothing
Set objShellApp = Nothing

Um agradecimento especial ao Syberdoor que me ajudou a descobrir o código do explorador de arquivos ( Descompacte o File Explorer a partir da barra de tarefas do Windows 10 por script ou arquivo em lote )