Como desativar a hover tooltip nas guias

Question

Existe uma maneira de desativar dicas de ferramentas suspensas em guias no Chrome?

Eles podem ficar muito irritantes e perturbadores sempre que o ponteiro do mouse estiver em uma guia.

    

Answer 1

Você não pode desativar essas dicas no Chrome.

Via: link link link

    

Answer 2

Não consegui obter a ideia de um programa a mover o cursor para você fora da minha mente, então eu joguei um juntos.

Abaixo está um script AutoHotkey (que pode ser compilado para um executável autônomo, se desejado) que detecta quando o cursor do mouse ficou inativo perto da parte superior de uma janela do Google Chrome por algum tempo e, se estiver, move-o para a parte inferior direita canto da tela.

Funciona como esperado e evita que as dicas de ferramentas sejam exibidas, mas devido ao tempo escalonado (o acionamento da sub-rotina e a contagem regressiva da dica de ferramenta), às vezes a dica é exibida por um segundo antes do cursor ser movido. Isso pode ser reduzido diminuindo o timer (a variável tip ).

Eu também estou pensando em aprimorar o script manipulando o cronômetro manualmente em vez de usar o cronômetro do AutoHotkey. Dessa forma, ele pode contar desde a última vez em que o mouse foi movido ou o botão pressionado, em vez de apenas todos os segundos x , independentemente disso.

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;   MoveIdleMouse.ahk
;
; Prevents tooltips from being annoying in Chrome by detecting
; when the mouse is idle while near the top of a Chrome window
; and then moving it to the bottom-right corner of the screen.
;
; https://superuser.com/questions/393738/
;
;   (cl) 2013- Synetech inc., Alec Soroudi
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

#SingleInstance force
#Persistent

; Read the tooltip delay from the registry (this is the amount of time the
; cursor has to hover over something in order to trigger the tooltip)
RegRead, tip, HKCU, Control Panel\Mouse, MouseHoverTime

; Divide it by two to accommodate staggared timing. Adjust as desired.
;tip:=tip/2

; Set specified subroutine to run every so often (before tooltip triggered)
SetTimer, CheckCursor, %tip%

; Get the current mouse cursor position to compare to during first interval
MouseGetPos, x1, y1
return

; This subroutine checks the current cursor position and moves if idle
CheckCursor:
  ; First check if the cursor is over a Chrome window; ignore if not
  IfWinNotActive, ahk_class Chrome_WidgetWin_0
    return

  ; Next, check if any buttons are pressed and ignore if so
  if (GetKeyState("LButton") or GetKeyState("RButton") or GetKeyState("MButton")
      or GetKeyState("XButton1") or GetKeyState("XButton2"))
    return

  ; Get the current mouse position and check if it is both unchanged, and
  ; near the top of Chrome (position is relative to window by default)
  MouseGetPos, x2, y2
  If (((x1 = x2) and (y1 = y2))  and  ((y2 >= 0) and (y2 <= 27)))
  {
    ; Move the cursor to the bottom-right corner of the screen immediately
    ; You can adjust destination position as desired
    MouseMove, A_ScreenWidth+3, A_ScreenHeight+3, 0
  }
  else {
    ; Update current cursor position to compare to during the next interval
    x1 := x2
    y1 := y2
  }
  return