Exclua um novo rascunho de e-mail que você está editando no Outlook

Question

Usando o Outlook 2013. Quando você redige um novo e-mail, geralmente há uma maneira de se livrar dele, caso você não queira mais enviar o e-mail. Existe uma maneira de fazer isso no Outlook?

Eu tentei fechar a mensagem (e não salvar / manter quando solicitado), mas isso cria um novo item não lido na minha pasta de itens excluídos, fazendo com que ele acenda como uma árvore de Natal. Eu então tenho que ir manualmente para essa pasta para limpar o rascunho.

Estou procurando algo como o ícone da lixeira do Gmail. Uma maneira simples e simples de se livrar da mensagem de uma vez por todas. (Há ocasiões em que quero salvar um rascunho - apenas no caso -, mas com mais frequência não.)

ATUALIZAÇÃO: Você pode expor um botão "Excluir" na "Barra de Ferramentas de Acesso Rápido" na parte superior, o que resulta na exclusão do item da mensagem. Isso funciona no momento em que você acabou de começar a digitar um novo e-mail. Clicar em excluir destrói a mensagem após o aviso obrigatório. Mas (!), Assim que o email é salvo automaticamente (depois de algum tempo) ele entra na pasta Rascunhos. Apagar a mensagem neste ponto MANTÉM a mensagem como ela é simplesmente movida para Itens Excluídos.

Existe alguma configuração que pode fazer com que o Outlook imite o botão da lixeira do Gmail ao criar um novo e-mail? É um caso de uso tão simples: "Não quero enviar o e-mail que acabei de começar, mudei de idéia, me livre dele, apague todos os vestígios dele". Essa é outra falha de recursos da Microsoft?

    

Answer 1

1. Você pode escrever um script VBA que faça algo como Descartar marcando a mensagem como lida e removendo-a para Itens Excluídos . Depois disso, coloque o botão na janela de mensagens que executa a macro (usando Personalizar Faixa de Opções - > Macros).

Algo parecido com isto:

Sub Discard()
    On Error Resume Next
    Dim objItem As MailItem

    Set objInspector = ActiveInspector
    If Not objInspector Is Nothing Then
        Set objItem = objInspector.CurrentItem
        If Not objItem Is Nothing And Not objItem.Sent Then
            objItem.UnRead = False
            objItem.Delete
        End If
    End If
End Sub

2. O Quick Tweaks Add-In gratuito pode marcar todos os itens excluídos como lidos automaticamente.
3. SHIFT + DEL elimina mensagens selecionadas na lista de mensagens sem colocá-las Itens Excluídos .

Answer 2

Eu descobri uma maneira de marcar automaticamente os itens adicionados à pasta excluída como lidos. Com essa solução, não é necessário adicionar um botão vinculado a uma macro.

Basta adicionar o seguinte código a "ThisOutlookSession" no editor do VBA:

Private WithEvents deletedItems As Outlook.Items

Private Sub Application_Startup()
    Dim olApp As Outlook.Application
    Dim objNS As Outlook.NameSpace
    Set olApp = Outlook.Application
    Set objNS = olApp.GetNamespace("MAPI")
    'Default folder for deleted items
    Set deletedItems = objNS.GetDefaultFolder(olFolderDeletedItems).Items
End Sub

Private Sub deletedItems_ItemAdd(ByVal Item As Object)
    Dim deletedEmail As Outlook.MailItem
    If TypeName(Item) = "MailItem" Then
        Set deletedEmail = Item
        deletedEmail.UnRead = False
    End If
End Sub

Você precisará reiniciar o Outlook para que ele funcione.

Observe que isso será aplicado a todos os e-mails excluídos e não apenas aos rascunhos.

    

Answer 3

A versão atual do Outlook tem um monte de botões de ação no meio da borda direita da janela e há um X vermelho para descartar.

Concordo que a interface do usuário do Outlook é bastante terrível e não intuitiva, mas não deve haver necessidade de criar macros apenas para descartar uma mensagem de rascunho.

    

Answer 4

A versão que acabei usando tem código para remover o item de correio de Itens Excluídos após a exclusão.

Sub Discard()
    On Error Resume Next
    Dim objItem As MailItem

    Set objInspector = ActiveInspector
    If Not objInspector Is Nothing Then
        Set objItem = objInspector.CurrentItem
        If Not objItem Is Nothing And Not objItem.Sent Then
            'no EntryID exists for freshly created mail, but does for a draft
            MyEntryId = objItem.EntryID
            objItem.UnRead = False
            objItem.Delete
            If Not MyEntryId = "" Then
                Dim oDeletedItems As Outlook.Folder
                'Obtain a reference to deleted items folder
                Set oDeletedItems = Application.Session.GetDefaultFolder(olFolderDeletedItems)
                'Delete last item from Deleted Items
                oDeletedItems.Items.Item(oDeletedItems.Items.Count).Delete
            End If
        End If
    End If
End Sub