Como identificar sessões de terminal OpenVMS extras e depois terminá-las?

Question

OpenVMS DCL comando mostra que tenho três sessões ativas.

$ show users
  OpenVMS User Processes at 12-OCT-2014 20:44:29.57
Total number of users = 3,  number of processes = 6

Username  Node     Interactive  Subprocess   Batch
CWHII     ROSIE            3
EFRICHA   ROSIE            1
HEINER    ROSIE            2

Como faço para identificar os dois antigos e terminá-los?

    

Answer 1

Hmmm, eu geralmente uso ^ T (control-T) para ver 'quem sou eu' e $ SHOW US CWHII / FULL. Então atire para matar conforme necessário.

Se assumirmos que 'antigo' significa NÃO a sessão atual, então você escreve o seguinte:

$ type CLEAN_ME_UP.COM
$ ctx  = ""
$ this = F$GETJPI( "", "PRCNAM" )
$ user = F$GETJPI( "", "USERNAME" )
$ node = F$GETJPI( "", "NODENAME" )
$ temp = F$CONTEXT( "PROCESS", ctx, "USERNAME", user, "EQL" )
$ temp = F$CONTEXT ("PROCESS", ctx, "NODENAME", node, "EQL")
$! IF F$TYPE( ctx ) .NES. "PROCESS_CONTEXT" THEN EXIT
$loop:
$ pid  = F$PID( ctx )
$ IF pid .EQS. "" THEN EXIT
$ that = F$GETJPI( pid, "PRCNAM" )
$ IF this.EQS.that
$ THEN
$  WRITE SYS$OUTPUT pid, " new"
$ ELSE
$  WRITE SYS$OUTPUT pid, " old"
$ ENDIF
$ GOTO loop

• É claro que você deseja substituir o WRITE SYS $ OUTPUT por STOP / ID quando estiver satisfeito.
• Remova o contexto NODE se você quiser fazer isso para todos os processos mais antigos em cada nó.
• Considere F $ GETJPI ("", "LOGINTIM") se você realmente quiser usar "mais antigo" (filmar em pé?)

Felicidades, Hein

re-formatado:

$ ctx  = ""
$ this = F$GETJPI( "", "PRCNAM" )
$ temp = F$CONTEXT( "PROCESS", ctx, "USERNAME", F$GETJPI("","USERNAME"), "EQL" )
$ temp = F$CONTEXT ("PROCESS", ctx, "NODENAME", F$GETJPI("","NODENAME"), "EQL")
$! IF F$TYPE( ctx ) .NES. "PROCESS_CONTEXT" THEN EXIT
$loop:
$ pid  = F$PID( ctx )
$ IF pid .EQS. "" THEN EXIT
$ IF F$GETJPI( pid, "PRCNAM" ).NES.F$GETJPI("", "PRCNAM") THEN WRITE SYS$OUTPUT "STOP ",pid
$ GOTO loop

    

Answer 2

Identifique todos os processos que você está executando.

$ SHOW USER CWHII/FULL
      OpenVMS User Processes at 13-OCT-2014 16:13:46.49
    Total number of users = 1,  number of processes = 3

 Username  Node   Process Name    PID     Terminal
 CWHII     ROSIE  CWHII         20200117  TZA44:   (108.225.238.117)
 CWHII     ROSIE  _TZA18:       202000B4  TZA18:   (108.225.238.117)
 CWHII     ROSIE  _TZA33:       202000C9  TZA33:   (108.225.238.117)

Identifique o nome do processo atual solicitando um relatório de interrupção e status da DCL fazendo um Controle-T.

$ ^T
ROSIE::CWHII 16:13:49   (DCL)   CPU=00:02:48.66 PF=15943 IO=9693 MEM=245

Mate os dois que não têm esse nome de processo.

$ STOP/IDENTIFICATION=202000B4
$ STOP/IDENTIFICATION=202000C9

Os PIDs inferiores nos dois confirmam que são os processos mais antigos.

Esta é uma informação para um método interativo para referência sem usar um script baseado nas informações em Hein resposta.