Excel aumentar carta apenas a cada linha

Question

Eu quero obter muitos dados da Planilha1 para a Planilha2, mas quando eu puxo um comando para a direita, ele só deve aumentar o "C" para um "D" a cada terceira linha. Porque eu tenho 3 comandos para puxar para a direita e todos devem ser aumentados por um não por 3.

A1 tem esta aparência:

=WENN(Sheet1!C3>0;Sheet1!C$2;"")

B1 assim:

=WENN(Sheet1!C3>0;Sheet1!$A3;"")

C1 assim:

=WENN(Sheet1!C3>0;Sheet1!C3;"")

Quando eu puxo para a direita eles mudam assim:

=WENN(Sheet1!F3>0;Sheet1!F$2;"")
=WENN(Sheet1!F3>0;Sheet1!$A3;"")
=WENN(Sheet1!F3>0;Sheet1!F3;"")

Mas eu quero:

=WENN(Sheet1!D3>0;Sheet1!D$2;"")
=WENN(Sheet1!D3>0;Sheet1!$A3;"")
=WENN(Sheet1!D3>0;Sheet1!D3;"")

Espero que você saiba o que quero dizer. Existe alguma maneira de fazer isso?

    

Answer 1

Você pode usar a função OFFSET útil, para controlar quanto deseja deslocar uma célula para a direita.

Como você deseja deslocar 1 coluna (na Folha1) a cada 3 colunas (na Folha2), você pode usar a seguinte função:

=ROUNDUP(COLUMN()/3,0)-1

Isso basicamente usará o número da coluna, dividida por 3 e arredondada. Então, nós removemos 1, porque não queremos mudar as 3 primeiras colunas. Se puxar isso para a direita, você obterá a seguinte seqüência: 0 0 0 1 1 1 2 2 2 3 3 3...

Agora você sabe o quanto você precisa mudar a célula C3 , você pode usar a função OFFSET para obter os dados corretos. Aqui estão as fórmulas que você deve usar em Sheet2 :

A1

=IF(OFFSET(Sheet1!$C3,0,ROUNDUP(COLUMN()/3,0)-1)>0,OFFSET(Sheet1!$C$2,0,ROUNDUP(COLUMN()/3,0)-1),"")

B1

=IF(OFFSET(Sheet1!$C3,0,ROUNDUP(COLUMN()/3,0)-1)>0,Sheet1!$A3,"")

C1

=IF(OFFSET(Sheet1!$C3,0,ROUNDUP(COLUMN()/3,0)-1)>0,OFFSET(Sheet1!$C3,0,ROUNDUP(COLUMN()/3,0)-1),"")

Resultado esperado:

VocêpareceestarusandooExcelemalemão.Aquiestãoasfórmulastraduzidas:

=WENN(BEREICH.VERSCHIEBEN(Sheet1!$C3;0;AUFRUNDEN(SPALTE()/3;0)-1)>0;BEREICH.VERSCHIEBEN(Sheet1!$C$2;0;AUFRUNDEN(SPALTE()/3;0)-1);"")
=WENN(BEREICH.VERSCHIEBEN(Sheet1!$C3;0;AUFRUNDEN(SPALTE()/3;0)-1)>0;Sheet1!$A3;"")
=WENN(BEREICH.VERSCHIEBEN(Sheet1!$C3;0;AUFRUNDEN(SPALTE()/3;0)-1)>0;BEREICH.VERSCHIEBEN(Sheet1!$C3;0;AUFRUNDEN(SPALTE()/3;0)-1);"")