Converta referências de notas de rodapé no Sistema de Referência de Harvard no MS Word

Question

Eu tenho doc com um monte de notas de rodapé, mas agora eu tenho que converter essas referências em Harvard Referencing System.

Exemplo:

Lorem ipsum dolor sit amet, consectetur adipiscing elit¹. Sed ac purus a sem sagittis dignissim.
...
¹ Curabitur at sapien feugiat

para:

Lorem ipsum dolor sit amet, consectetur adipiscing elit [Curabitur at sapien feugiat]. Sed ac purus a sem sagittis dignissim.

Alguém pode me ajudar com isso?

EDITAR:
Eu tenho o Office 2007 e 2013.

    

Answer 1

Esta macro faz exatamente o que você quer. Veja como usá-lo (com capturas de tela na parte inferior)

Observação: essa macro desativa o desfazer ao final de cada movimento da nota de rodapé, portanto, mantenha um backup do documento ANTES de fazer qualquer coisa, caso não faça exatamente o que você quer !! Você pode reativar desfazer removendo a terceira para a última e a quarta para a última linhas, mas eu não a recomendo se você tiver um documento muito grande !!

Para configurar isso no Office 2013 (no mesmo link acima, editei para o Office 2013):

1) Pressione Alt + F11

2) Na parte superior da barra de menus, clique em Inserir > Módulo

3) Na janela principal, copie e cole a macro abaixo

4) Na janela de propriedades, renomeie o módulo para qualquer nome desejado e o nome na janela da esquerda se você alterar o nome do módulo.

5) Salve Normal e Feche o editor

6) Pressione Alt + F8, escolha a macro e pressione Run

Macro (eu editei para que funcione como no seu exemplo). Você pode alterar o código de cor para o que quiser. Você quer o valor decimal para cores - é preto por padrão:

Sub foot2inline()
Dim oFeets As Footnotes
Dim oFoot As Footnote
Dim oRange As Range
Dim szFootNoteText As String

' Grabs the collection of FootNotes
Set oFeets = Word.ActiveDocument.Footnotes

' Iterates through each footnote
For Each oFoot In oFeets      

    szFootNoteText = oFoot.Range.Text

    'Start search from beginning of document
    Selection.HomeKey Unit:=wdStory
    Selection.Find.ClearFormatting

    With Selection.Find
        .Text = "^f" ' Looks for all footnotes
        .Forward = True
        .Wrap = wdFindStop
    End With

    Selection.Find.Execute
    ' Delete the footnote
    oFoot.Delete

    'Insert the footnote text
    'Here you do whatever format tickles your fancy
    'The only thing you need to keep is the speech marks and 'szFootNotetext'
    'Make sure anything you want to surround the citations is inside speech marks.
    'For example = " (" + szFootNoteText + ") "
    Selection.Text = " [" + szFootNoteText + "] "

    'CHANGE COLOR HERE. Color code is below.
    Selection.Font.Color = 0

    'Disables undo to save memory on very large documents.
    ActiveDocument.UndoClear
Next
End Sub

Screenshots:

Configurando a macro: Seudocumentocomnotasderodapé: Usando a macro: Seudocumentocomseusistemadereferência:

    

Answer 2

Funciona como um encanto.
Eu mudei um pouco sua macro para que isso adicione o conteúdo da nota de rodapé em fontes bibliográficas (como um título) e insira a citação no lugar da referência da nota de rodapé.

talvez alguém use isso:

Sub foot2inline()
Dim oFeets As Footnotes
Dim oFoot As Footnote
Dim oRange As Range
Dim szFootNoteText As String

' Grabs the collection of FootNotes
Set oFeets = Word.ActiveDocument.Footnotes
Dim tagNumber As Integer
tagNumber = 1
' Iterates through each footnote
For Each oFoot In oFeets

    szFootNoteText = oFoot.Range.Text

    'Start search from beginning of document
    Selection.HomeKey Unit:=wdStory
    Selection.Find.ClearFormatting

    With Selection.Find
        .Text = "^f" ' Looks for all footnotes
        .Forward = True
        .Wrap = wdFindStop
    End With

    Selection.Find.Execute
    ' Delete the footnote
    oFoot.Delete

    'Insert the footnote text
    'Here you do whatever format tickles your fancy
    'The only thing you need to keep is the speech marks and 'szFootNotetext'
    'Make sure anything you want to surround the citations is inside speech marks.
    'For example = " (" + szFootNoteText + ") "

    Dim tag As String
    tag = "Tag" + CStr(tagNumber)

    Selection.Fields.Add Selection.Range, _
            wdFieldCitation, tag

    Dim strXml As String
    strXml = _
        "<b:Source xmlns:b=""http://schemas.microsoft.com/" & _
        "office/word/2004/10/bibliography""><b:Tag>" & tag & "</b:Tag>" & _
        "<b:SourceType>Book</b:SourceType><b:Author><b:Author>" & _
        "<b:NameList><b:Person><b:Last>LastName</b:Last>" & _
        "<b:First>FirstName</b:First></b:Person></b:NameList></b:Author>" & _
        "</b:Author><b:Title>" & szFootNoteText & "</b:Title>" & _
        "<b:Year>1996</b:Year><b:City>City</b:City>" & _
        "<b:Publisher>Publisher</b:Publisher>" & _
        "</b:Source>"

    ActiveDocument.Bibliography.Sources.Add (strXml)

    'CHANGE COLOR HERE. Color code is below.
    Selection.Font.Color = 0

    'Disables undo to save memory on very large documents.
    ActiveDocument.UndoClear
    tagNumber = tagNumber + 1
Next
End Sub