Use perl para fazer a substituição de várias linhas [closed]

Question

Eu tenho que fazer algumas substituições em muitos arquivos *.c . Eu quero fazer a substituição assim:
original: printf("This is a string! %d %d\n", 1, 2);
resultado: print_record("This is a string! %d %d", 1, 2);
Ou seja, substitua o " printf " por " print_record " e remova o " \n " à direita.
No começo, eu uso sed para fazer essa tarefa. No entanto, talvez haja alguns casos como este:

printf("This is a multiple string, that is very long"
 " and be separated into multiple lines. %d %d\n", 1, 2); 

Nesse caso, não posso usar sed para remover facilmente o " \n ". Ouvi dizer que perl pode fazer isso funcionar bem. Mas estou fresco para perl . Então, alguém pode me ajudar? Como fazer isso com perl ?
Muito obrigado!

    

Answer 1

O que você quer fazer não é trivial. Ele requer alguma análise para cuidar de delimitadores balanceados, citando, e a regra C de que os literais das cadeias adjacentes sejam unidos em um único. Felizmente, o módulo Perl Text :: Balanced lida com muito disso (Text :: Balanced está disponível no Perl ') biblioteca padrão). O script a seguir deve fazer mais ou menos o que você deseja. É necessário um argumento de linha de comando e saídas na saída padrão. Você terá que envolvê-lo dentro de um script de shell. Eu usei o seguinte wrapper para testá-lo:

#/bin/bash
find in/ -name '*.c' -exec sh -c 'in="$1"; out="out/${1#in/}"; perl script.pl "$in" > "$out"' _ {} \;
colordiff -ru expected/ out/

E aqui está o script Perl. Eu escrevi alguns comentários, mas fique à vontade para perguntar se você precisa de mais explicações.

use strict;
use warnings;
use File::Slurp 'read_file';
use Text::Balanced 'extract_bracketed', 'extract_delimited';

my $text = read_file(shift);

my $last = 0;
while ($text =~ /(          # store all matched text in $1
                  \bprintf  # start of literal word 'printf'
                  (\s*)     # optional whitespace, stored in $2
                  (?=\()    # lookahead for literal opening parenthesis
                 )/gx) {
    # after a successful match,
    #   1. pos($text) is on the character right behind the match (opening parenthesis)
    #   2. $1 contains the matched text (whole word 'printf' followed by optional
    #      whitespace, but not the opening parenthesis)
    #   3. $2 contains the (optional) whitespace

    # output up to, but not including, 'printf'
    print substr($text, $last, pos($text) - $last - length($1));
    print "print_record$2(";

    # extract and process argument
    my ($argument) = extract_bracketed($text, '()');
    process_argument($argument);

    # save current position
    $last = pos($text);
}

# output remainder of text
print substr($text, $last);

# process_argument() properly handles the situation of a format string
# consisting of adjacent string literals
sub process_argument {
    my $argument = shift;

    # skip opening parenthesis retained by extract_bracketed()
    $argument =~ /^\(/g;

    # scan for quoted strings
    my $saved;
    my $last = 0;
    while (1) {
        # extract quoted string
        my ($string, undef, $whitespace) = extract_delimited($argument, '"');
        last if !$string;       # quit if not found

        # as we still have strings remaining, the saved one wasn't the last and should
        # be output verbatim
        print $saved if $saved;
        $saved = $whitespace . $string;
        $last = pos($argument);
    }
    if ($saved) {
        $saved =~ s/\n"$/"/;   # chop newline character sequence off last string
        print $saved;
    }

    # output remainder of argument
    print substr($argument, $last);
}