Automatizar tarefas no OSX como VPN Connection?

Question

Estou usando o serviço VPN da minha escola para navegar no Netflix. Eu tenho que me conectar à VPN na maioria das vezes. Minha escola usa o Cisco AnyConnect Secure Mobility Client. Eu tenho que digitar a senha e aceitar um banner toda vez que eu conectar. Existe uma maneira de automatizar essa conexão no OS X?

    

Answer 1

Se você estiver usando o OS X para controlar sua conexão:

A razão pela qual isso ocorre é porque a caixa da Cisco à qual você está se conectando está forçando a interação. Na verdade, é uma configuração no agregador de VPN da Cisco que reforça a segurança. A Apple não fornece informações para (Apple Script / Automator) isso como parte do acordo que a Cisco fez com a Apple (de acordo com a Cisco e a Apple). Eu já investiguei isso antes e esta foi a resposta que me foi dada por ambos os lados.

O mesmo acontece com o cliente VPN do Cisco OS X.

    

Answer 2

Sim, você pode automatizar isso usando o AppleScript.

Aqui está um script que eu uso:

-- 1. Place in ~/Library/Scripts and enable the Applescript menu via the Applescript Editor
--    (Or export to .app to run from spotlight.)
-- 2. Substitute "vpn.example.com", "username" and "redacted" for your VPN server and password
-- 3. Open Security & Privacy System Preferences, go to Privacy, Accessibility
-- 4. Enable Applescript Editor and System UI Server (or for this .app if so exported)
-- 5. Trigger script from the menu (or run from spotlight)
-- 6. Enjoy being connected
-- 7. Run script again to close connection


-- AnyConnect now refered to as targetApp
set targetApp to "Cisco AnyConnect Secure Mobility Client"


-- Determine if AnyConnect is currently running
tell application "System Events"
    set processExists to exists process targetApp
end tell


-- Close connection if running; else start connection and fill in password
if processExists is true then
    tell application targetApp
        quit
    end tell
else
    tell application targetApp
        activate
    end tell

    tell application "System Events"
        repeat until (window 1 of process targetApp exists)
            delay 1
        end repeat
        tell process targetApp
            keystroke ("vpn.example.com" as string)
            keystroke return
        end tell
        repeat until (window 2 of process targetApp exists)
            delay 1
        end repeat
        tell process targetApp
            keystroke (tab) using {shift down}
            keystroke ("username" as string)
            keystroke tab
            keystroke ("redacted" as string)
            keystroke return
        end tell
        delay 1
        tell process targetApp
            keystroke return
        end tell

    end tell
end if

Este é um script que encontrei e ajustei; Não tenho certeza de quem é o autor original, pois há várias versões flutuando. Eu peguei de link