Como emular a hiper-chave no Windows 10 usando o autocuidado

Question

Estou migrando meu fluxo de trabalho do Mac para o Windows. Uma coisa que eu não poderia viver sem é hyper key que é a combinação de Ctrl + Option + Shift + Cmd . Eu uso o aplicativo Karabiner para remapear Capslock para essa chave Hyper . Ouvi dizer que o Autohotkey é uma alternativa do Karabiner para Windows . Vocês poderiam me ajudar a imitar esse recurso no Windows?

Meu resultado ideal é:

• Desative Capslock completamente porque raramente uso isso
• Alternar Capslock executará ESC chave
• Mantenha pressionado Capslock e execute Ctrl + Alt + Shift + Windows . Por exemplo, Capslock + C será Ctrl+Alt+Shift+Windows+C

Muito obrigado antecipadamente!

Na tentativa de resolver meu problema, escrevi algumas linhas de código, mas não funciona. Por favor me ajude a apontar meu erro:

;-----------------------------------------
; hyper key for windows
;=========================================

; --------------------------------------------------------------
; notes
; --------------------------------------------------------------
; ! = alt
; ^ = ctrl
; + = shift
; # = lwin|rwin
;
#NoEnv ; recommended for performance and compatibility with future autohotkey releases.
#UseHook
#InstallKeybdHook
#SingleInstance force

SendMode Input

;; deactivate capslock completely
SetCapslockState, AlwaysOff

;; remap capslock to hyper
;; if capslock is toggled, remap it to esc

Capslock::
    SendInput {Ctrl Down}{Alt Down}{Shift Down}{LWin Down}
    KeyWait, Capslock
    SendInput {Ctrl Up}{Alt Up}{Shift Up}{LWin Up}
    if (A_PriorKey = "Capslock") {
        SendInput {Esc}
    }
return

;; vim navigation with hyper
~^!+#h:: SendInput {Left}
~^!+#l:: SendInput {Right}
~^!+#k:: SendInput {Up}
~^!+#j:: SendInput {Down}

;; popular hotkeys with hyper
~^!+<#c:: SendInput ^{c}
~^!+<#v:: SendInput ^{v}

Resultado:

• Toggle Capslock executa ESC
• Mantenha o Capslock executando a combinação de teclas Ctrl + Alt + Shift + Win
• Pressione Ctrl + Alt + Shift + Win com h, j, k, l, c, v e funcione como esperado
• No entanto Segure o Capslock com h, j, k, l, c, v não funciona

Answer 1

Obrigado por qualquer um que esteja tentando me ajudar, eu descobri o problema por conta própria e gostaria de compartilhá-lo no caso de alguém se deparar com este prob.

#NoEnv ; recommended for performance and compatibility with future autohotkey releases.
#UseHook
#InstallKeybdHook
#SingleInstance force

SendMode Input

;; deactivate capslock completely
SetCapslockState, AlwaysOff

;; remap capslock to hyper
;; if capslock is toggled, remap it to esc

;; note: must use tidle prefix to fire hotkey once it is pressed
;; not until the hotkey is released
~Capslock::
    ;; must use downtemp to emulate hyper key, you cannot use down in this case 
    ;; according to http://bit.ly/2fLyHHI, downtemp is as same as down except for ctrl/alt/shift/win keys
    ;; in those cases, downtemp tells subsequent sends that the key is not permanently down, and may be 
    ;; released whenever a keystroke calls for it.
    ;; for example, Send {Ctrl Downtemp} followed later by Send {Left} would produce a normal {Left}
    ;; keystroke, not a Ctrl{Left} keystroke
    Send {Ctrl DownTemp}{Shift DownTemp}{Alt DownTemp}{LWin DownTemp}
    KeyWait, Capslock
    Send {Ctrl Up}{Shift Up}{Alt Up}{LWin Up}
    if (A_PriorKey = "Capslock") {
        Send {Esc}
    }
return

;; vim navigation with hyper
~Capslock & h:: Send {Left}
~Capslock & l:: Send {Right}
~Capslock & k:: Send {Up}
~Capslock & j:: Send {Down}

;; popular hotkeys with hyper
~Capslock & c:: Send ^{c}
~Capslock & v:: Send ^{v}