Como alterar o estilo de cor padrão do SmartArt no Office?

Question

Atualmente, estou criando um novo modelo de powerpoint para nossos pequenos negócios. Como parte disso, queremos poupar tempo às pessoas, selecionando as cores certas automaticamente quando criam gráficos usando o SmartArt.

Mudar para uma cor diferente é realmente simples, um exemplo é dado aqui: link

Minha pergunta é: É possível alterar qual desses esquemas de cores é usado como padrão ao criar novos gráficos. Minha cor de destaque principal é azul, então o gráfico padrão preencheu as formas azuis com texto branco. Eu gostaria que o padrão fosse apenas um contorno azul com um fundo branco e texto preto. Esta é outra das opções disponíveis, mas não o padrão atual.

Isso economizaria muito tempo para nossos funcionários na criação de diagramas.

    

Answer 1

Infelizmente, não há (como no PowerPoint 2013) nenhuma maneira de definir o formato padrão para o SmartArt ou usar o Pincel para formatar todas as formas em um gráfico SmartArt.

Mas, sempre que uma pergunta como essa surgir, as macros e suplementos do VBA são resgatados.

A macro muito básica abaixo pega a linha e preenche a cor da sua forma selecionada ou do estilo de forma padrão, se você não selecionar nada e aplicá-la a cada forma no gráfico SmartArt. Se você não souber usar uma macro, dê uma olhada nestes exemplos:

link

É básico porque há literalmente centenas de propriedades que um usuário pode definir, como gradientes de preenchimento, imagens, texturas, cores de linha, larguras, traços e efeitos como reflexão, brilho, etc.

Eu possuo uma empresa chamada GMARK especializada em desenvolvimento de suplementos do PowerPoint ( link ) e poderia criar um suplemento para faça isso se houver interesse.

Sub SetSmartArtToDefaultShapeStyle() 
Dim oSld As Slide 
Dim oShpCheck As Shape, oShpSource As Shape, oShpNode 
Dim oNode As SmartArtNode 
Dim DeleteShape As Boolean

On Error GoTo errorhandler

Set oSld = ActivePresentation.Slides(ActiveWindow.View.Slide.SlideIndex)

If Not ActiveWindow.Selection.HasChildShapeRange Then 
  Set oShpSource = oSld.Shapes.AddShape(msoShapeRectangle, 0, 0, 10, 10) 
  DeleteShape = True 
Else 
  Set oShpSource = ActiveWindow.Selection.ShapeRange(1) 
End If

oShpSource.PickUp

For Each oShpCheck In oSld.Shapes ' As Shapes 
  With oShpCheck 
    If .HasSmartArt Then 
      For Each oNode In .SmartArt.Nodes 
        For Each oShpNode In oNode.Shapes ' As ShapeRange 
          With oShpNode 
            .Line.Visible = oShpSource.Line.Visible 
            .Fill.Visible = oShpSource.Line.Visible 
            If .Line.ForeColor.Type = msoColorTypeRGB Then _ 
              .Line.ForeColor.RGB = oShpSource.Line.ForeColor.RGB 
            If .Line.ForeColor.Type = msoColorTypeScheme Then _ 
              .Line.ForeColor.ObjectThemeColor = oShpSource.Line.ForeColor.ObjectThemeColor 
            If .Fill.ForeColor.Type = msoColorTypeRGB Then _ 
              .Fill.ForeColor.RGB = oShpSource.Fill.ForeColor.RGB 
            If .Fill.ForeColor.Type = msoColorTypeScheme Then _ 
              .Fill.ForeColor.ObjectThemeColor = oShpSource.Fill.ForeColor.ObjectThemeColor 
          End With 
        Next 
      Next 
    End If 
  End With 
Next

If DeleteShape = True Then oShpSource.Delete

Exit Sub

errorhandler: 
MsgBox "There was an error : " & Err.Number & " : " & Err.Description, vbCritical + vbOKOnly, "SmartArt Format by i-present.co.uk" 
Err.Clear 
If DeleteShape = True Then oShpSource.Delete 
End Sub

    

Answer 2

Aqui está uma maneira muito mais fácil de alterar a cor padrão usada com os gráficos SmartArt. Eu só testei isso com o PowerPoint 2010. Você precisa alterar a paleta de cores. Não tem 100% de certeza de que é isso que você está procurando, mas pode ajudar outras pessoas.

Na guia Design, selecione o menu suspenso Cores. Selecione Criar novas cores de tema e altere a cor Accent 1 para a cor desejada para a cor SmartArt padrão.

Observe, no entanto, que isso pode afetar itens como as cores dos marcadores nos slides. Isso também pode ser alterado indo para o slide mestre, selecione o modelo de slide de nível superior, selecione a janela de texto que contém os marcadores de slide, no menu inicial, selecione o marcador, marcadores e numeração e você encontrará a cor do marcador configurações.