Como definir uma notificação sonora de 100% da bateria? [duplicado]

Question

Podemos definir uma notificação de som de bateria fraca / crítica , mas não sei como definir uma notificação de som de bateria cheia, Existe alguma maneira de fazer isso?

EDIT: Eu concordo com o ponto que nem todos os laptops cobram 100%, então minha pergunta é reformulada de 100% a 95%, ou talvez para obter uma notificação em uma determinada% de idade ...

    

Answer 1

Não consigo definir uma notificação sonora completa da bateria. Existe alguma maneira de fazer isso?

Use o seguinte arquivo de lote (Battery.cmd):

@echo off
setlocal EnableDelayedExpansion
rem set threshold value
set _threshold=95
:start
rem get the battery charge
rem use findstr to strip blank lines from wmic output
for /f "usebackq skip=1 tokens=1" %%i in ('wmic Path Win32_Battery Get EstimatedChargeRemaining ^| findstr /r /v "^$"') do (
  set _charge=%%i
  echo !_charge!
  if !_charge! geq !_threshold! (
    echo charge reached
    goto :done
    ) else (
    rem wait for 10 minutes then try again
    timeout /t 600 /nobreak
    goto :start
    )
  )
:done
endlocal

Notas:

• Este arquivo em lote monitora a carga percentual atual da bateria e imprime "carga atingida" quando a carga alcança um valor limite definido pelo usuário (neste caso, 95%). O arquivo em lotes, em seguida, termina. Se a cobrança ficar abaixo do limite, o usuário deverá executar manualmente o arquivo de lote novamente.
• Defina _threshold conforme necessário.
• Substitua o comando echo charge reached por um comando para reproduzir o som escolhido.
  • Se você quiser criar um evento definido pelo usuário (no log de eventos) em vez de reproduzir um som, consulte a minha resposta ID do evento do Windows para alteração do nível da bateria .
• Modifique o atraso de timeout conforme necessário para sua situação.

Leitura Adicional

• Um índice AZ da linha de comando do Windows CMD - Uma excelente referência para todas as coisas relacionadas à linha do Windows cmd.

• wmic - Comando de instrumentação de gerenciamento do Windows.