Existem alguns erros no seu script, por exemplo (talvez incompletos):
(1) E se um usuário apenas pressionar ENTER em resposta a set /p YN= ? Use aspas duplas da seguinte forma: IF "%YN%"=="1" ( ou considere mudar para CHOICE command que permite que capturas de teclas únicas sejam capturadas o teclado.
(2) Por que você usa a mesma variável gameMode para armazenar coisas tão diferentes?
(3 - important ) O parêntese de fechamento em echo choose your second card(1-4) usado em um bloco de código entre parênteses fecharia. Ou escape como echo … card(1-4^) ou use parênteses de outra forma, por ex. colchetes como em echo … card [1-4] .
(4 - mais importante ) Nunca use :label nem :: label-like comment dentro de um bloco de comando entre () parênteses. Crie e Chame uma sub-rotina . Você pode goto ad libitum dentro de tal corpo de procedimento.
(5) %RANDOM% dentro de um bloco de comandos entre () parênteses é avaliado para o mesmo número. Portanto, todos os card1 , card2 , card3 e card4 no snippet de código a seguir são os mesmos:
IF "!gameMode!"=="0" (
set /a card1=%RANDOM% %%96
set /a card2=%RANDOM% %%96
set /a card3=%RANDOM% %%96
set /a card4=%RANDOM% %%96
)
Além disso, nem mesmo usar !RANDOM! em vez de %RANDOM% poderia garantir valores diferentes. Compare o procedimento :dragNthCard abaixo.
Comentário útil de Dbenham me inspirou a brincar um pouco com o seu código. Aqui está um rascunho cru (trabalhando em algum sentido que não poderia corresponder perfeitamente ao seu objetivo). Implementou LCM e GCF como teste de uma rodada para o iniciador P1 e juntou-se a P2 : a mesma tarefa, conjuntos de cartões diferentes.
@ECHO OFF
SETLOCAL EnableExtensions EnableDelayedExpansion
:Start
@echo note:game must be started for P2 to join
CHOICE /C 12Q /M "start game (1) or join game (2) or quit game (Q)"
set "YN=%errorlevel%"
IF errorlevel 3 goto :eof
IF errorlevel 2 (
@echo joining game...
@echo true> quizFiles/P2Joined.txt
timeout /t 1 /nobreak > NUL
@echo joined
) ELSE (
@echo creating files...
if not exist quizFiles md "quizFiles"
@echo P1> quizFiles/gameState.txt
@echo 48> quizFiles/cards.txt
@echo.0> quizFiles/P1Score.txt
@echo.0> quizFiles/P2Score.txt
@echo false> quizFiles/P2Joined.txt
set /a gameMode=%RANDOM% %%4
echo gameMode !gameMode!
@echo.!gameMode!> quizFiles/gameMode.txt
timeout /t 1 /nobreak > NUL
@echo waiting for other player to join...
call :waitToJoin
)
rem commont part for both initiator P1 and joined P2
call :dragCards
REM currently implemented only one round game
REM
REM set /p cardsRemaining=<quizFiles/cards.txt
REM @echo cards left: !cardsRemaining!
REM set /p P1Score=<quizFiles/P1Score.txt
REM @echo P1 has: !P1Score! cards
REM set /p P2Score=<quizFiles/P2Score.txt
REM @echo P2 has: !P2Score! cards
REM set /p currentPlayer=<quizFiles/gameState.txt
REM @echo It is now !currentPlayer!'s turn
REM
@echo 4 cards chosen
set /p gameMode=<quizFiles/gameMode.txt
IF "!gameMode!"=="0" (
set gameModeText=LCM
) ELSE IF "!gameMode!"=="1" (
set gameModeText=GCF
) ELSE IF "!gameMode!"=="2" (
set gameModeText=Multiplication of fractions
) ELSE IF "!gameMode!"=="3" (
set gameModeText=Division of fractions
)
echo gameMode !gameMode! !gameModeText!
set "rightAnswer=nonsens"
IF "!gameMode!"=="0" (
call :Choose2Cards
call :%gameModeText% !chosenCard1! !chosenCard2!
)
IF "!gameMode!"=="1" (
call :Choose2Cards
call :%gameModeText% !chosenCard1! !chosenCard2!
)
IF "!gameMode!"=="3" call :Choose2Cards & rem not implemented yet
IF "!gameMode!"=="4" call :Choose2Cards & rem not implemented yet
IF "%rightAnswer%"=="nonsens" (
echo not implemented yet: %gameModeText%
) else (
If "%userAnswer%"=="%rightAnswer%" (
echo %userAnswer% is right
) ELSE (
echo %userAnswer% is wrong; right answer = %rightAnswer%
)
)
rem PAUSE
:::::::::::::::::::::::::::::::
:::
::: Your script continues here: save score, loop next round etc.
:::
:::::::::::::::::::::::::::::::
ENDLOCAL
goto :eof
:LCM
rem Least common multiple usage: call :lcm <input1> <input2>
rem by https://rosettacode.org/wiki/Least_common_multiple#Batch_File
set "_aux1=%1"
set "_aux2=%2"
:lcmSub
if %2 equ 0 (
set /a rightAnswer = %_aux1%*%_aux2%/%1
rem echo rightAnswer = !rightAnswer!
goto :EOF
)
set /a res = %1 %% %2
call :lcmSub %2 %res%
goto :eof
:GCF
rem Greatest common factor / divisor
rem by https://rosettacode.org/wiki/Greatest_common_divisor#Batch_File
if %2 equ 0 (
set rightAnswer=%1
rem echo rightAnswer = !rightAnswer!
goto :eof
)
set /a res = %1 %% %2
call :gcf %2 %res%
goto :eof
:Muliplication
goto :eof
:Division
goto :eof
:waitToJoin
set dot="2"
:WP2
set /p P2Joined=<quizFiles/P2Joined.txt
IF NOT "!P2Joined!"=="true" (
timeout /t 2 /nobreak > NUL
@echo waiting...
GOTO WP2
)
@echo joined
goto :eof
:dragCards
:P1G
for /L %%N in (1,1,4) do (
call :dragNthCard %%N
echo card%%N: !card%%~N!
)
goto :eof
:Choose2Cards
CHOICE /C 1234 /M "choose your first card "
set "chosenCard1=!card%errorlevel%!"
:Choose2CardsDifferent
CHOICE /C 1234 /M "choose your second card "
set "chosenCard2=!card%errorlevel%!"
If %chosenCard1% EQU %chosenCard2% goto :Choose2CardsDifferent
echo what is the %gameModeText% of these two cards: %chosenCard1% and %chosenCard2%
set /p "userAnswer=%gameModeText%( %chosenCard1%, %chosenCard2%) = "
goto :eof
:dragNthCard
set "_cardNo=%~1"
set /A _cardMax=%_cardNo% - 1
:dragNthAgain
set /a card%_cardNo%=%RANDOM% %%96
for /L %%G in (1,1,%_cardMax%) do (
if !card%_cardNo%! EQU !card%%G! (
timeout /t 1 /nobreak > NUL
goto :dragNthAgain
)
)
rem echo CARD%_cardNo%: !card%_cardNo%!
goto :eof