Como removo o botão Atualizar da barra de ferramentas Endereço?

Question

Eu gosto de poder executar comandos diretamente da barra de tarefas. Então, eu ativei a barra de endereços no meu novo sistema Windows 7 - assim como eu tive no meu antigo sistema XP. No entanto, a barra parece ter um comprimento mínimo obrigatório (publiquei uma pergunta separada sobre isso) que é um pouco mais longa do que eu preferiria. Além disso, um pouco mais de espaço horizontal é consumido por um botão Atualizar no final dele.

Este botão Atualizar é semelhante ao botão Ir que costumava ser exibido por padrão em versões mais antigas. Esse botão foi facilmente removido, alterando um valor de registro que parece não existir no Windows 7. Existe um hack de registro similar que eu possa usar para remover o novo botão Atualizar?

    

Answer 1

Como eu disse em sua outra pergunta, não há uma maneira interna de modificar a barra de endereço. Você precisará usar um programa de terceiros que seja executado em segundo plano e modifique as propriedades da barra de endereço para ajustar seu tamanho e ocultar o botão de atualização.

Infelizmente, não conheço nenhum desses programas, nem posso encontrar nenhum. Eu tenho uma ferramenta que eu mesmo escrevi semelhante a WinSpy ++ , mas enquanto meu programa e WinSpy ++ podem ser usados para altere o comprimento e oculte o botão manualmente, nenhum deles é executado em segundo plano para detectar sempre que a barra de endereços é criada e realizar as modificações automaticamente.

Uma coisa que você pode tentar é usar um tipo de programa de teclas de atalho / macro que permita definir acionadores para realizar eventos e definir um acionador como window created - address-bar... e definir o evento como hide refresh button; set address-bar length=... . Isso provavelmente pode ser realizado com AutoHotkey ou AutoIt também.

Esta é a porta AutoHotKey do meu programa C ++ para remover o botão de atualização. (Ele pode ser compilado e executado em segundo plano.)

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; NoAddressBarButton.ahk (http://superuser.com/questions/444406/)
;
; This script hides the refresh button of the address-bar band of the Windows 7
; taskbar. It also extends the combo-box (edit field) to use the space of the
; refresh button.
;
;   (cl) 2012- Synetech inc., Alec Soroudi
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

#NoTrayIcon                                       ;No tray icon, duh
#NoEnv                                            ;Not using environment vars
#SingleInstance Force                             ;Use only a single instance
#Persistent                                       ;Using a timer loop; keep open

SetTimer, Run, 1000                               ;Re-run the check every second

Run:
IfWinExist ahk_class Shell_TrayWnd                ;Check if taskbar exists
{
  ControlGet, tv, Visible, ,  ToolbarWindow323    ;Is refresh button visible?
  ControlGetPos, tx,ty,tw,th, ToolbarWindow323    ;Get button width
  ControlGetPos, cx,cy,cw,ch, ComboBoxEx321       ;Get combobox width
  ControlGetPos, mx,my,mw,mh, msctls_progress321  ;Get address-bar width
  if ((tv==1) || (cw<mw))                         ;If button visible
                                                  ;or resized (combobox is short)
  {
    Control, Hide,, ToolbarWindow323              ;(Re-)hide the refresh button
    ControlGetPos, cx,cy,cw,ch, ComboBoxEx321     ;Get current combobox width
    cw:=cw+tw                                     ;Add the button width
    ControlMove, ComboBoxEx321, , , %cw% ,        ;Extend combobox to include button
  }
}