AutoHotKey como passar / avaliar parâmetros para funções

Question

Estou tendo problemas para entender como os parâmetros são acessados nas funções da AutoHotKey.

Por exemplo, eu configuro a variável myVar com o InputBox, depois a transmito para uma função. Como faço para avaliar o argumento no TestFunction?

#t::
    inputbox myVar, What is your variable?
    myNewVar := TestFunction(%myVar%)
    MsgBox %myNewVar% 
    return

TestFunction(arg)
{
    MsgBox arg
    msgBox %arg%
    return %arg%
}    

O que eu quero fazer é configurar uma tecla de atalho que solicitará uma palavra-chave para um aplicativo e, em seguida, avaliará o que foi inserido na função e acionará qualquer aplicativo que corresponda a essa palavra-chave.

Obrigado!

Chris

    

Answer 1

Eu corrigi seu script (como Bavi_H sugeriu) e adicionei um exemplo para iniciar um aplicativo correspondente a uma palavra-chave.

#t::
inputbox myVar, What is your variable?
myNewVar := TestFunction(myVar)
MsgBox %myNewVar% 
return

TestFunction(arg)
{
    msgBox %arg%
    if (arg = "calc")
    {
        run, calc.exe
    }
    else if (arg = "word")
    {
        run, winword.exe
    }
    return arg . "bob"
}

    

Answer 2

Basicamente, os comandos, como run, %something% , são diferentes das funções, como myFunction(something) . Aqui está outro exemplo baseado na resposta de qwertzguy

#t::
    ; get variable from message box
    inputbox myVar, What is your variable?

    ; myVar DOES NOT have percents when passed to function
    myNewVar := TestFunction(myVar)

    ; myNewVar DOES have percents when passed to command
    MsgBox %myNewVar% 

return


TestFunction(arg)
{
    ; command DOES have percents 
    MsgBox Launching: %arg%

    if (arg = "calc")
    {
        ; commands use traditional variable method
        ; traditional method example: Var = The color is %FoundColor%
        ; variables are evaluated inside quotes

        run, "%A_WinDir%\system32\calc.exe"
    }
    else if (arg = "word")
    {

        ; functions need to use expression version since percents are not evaluated
        ; expression method example: Var := "The color is " . FoundColor
        ; variables are not evaluated inside quotes

        EnvGet, ProgramFilesVar, ProgramFiles(x86)
        OfficeVersionVar := "15"

        RunFunction(ProgramFilesVar . "\Microsoft Office\Office" . OfficeVersionVar . "\WINWORD.EXE")

    }

    return "You typed: " . arg

}



RunFunction(arg)
{
    run, %arg%
}