Como desabilitar / habilitar a área de transferência do escritório

Question

Pergunta: Existe alguma maneira de desativar a área de transferência no Office 2016?

Não me refiro a mostrar / ocultar o status ao lidar com coisas semelhantes às opções da área de transferência. Eu quero desligar completamente. É tão intrusivo que você não pode desligá-lo do próprio aplicativo. Também é uma preocupação de privacidade, porque tudo o que você copia no seu dispositivo vai para lá se qualquer aplicativo (Excel, Word, etc.) estiver aberto. Se todos eles estiverem fechados, copiará a área de transferência do sistema para a área de transferência do Office quando você iniciar o Word / Excel.

Eu estou procurando por qualquer tipo de solução (de terceiros, registro, etc ...). Eu tenho o Win 7/64 bit e o Office 2016/64 bit.

    

Answer 1

Desativando a área de transferência

Abaixo está um método para desativar a funcionalidade da área de transferência usando um script em lotes com alguma lógica condicional e um loop. Há também um método e algumas instruções abaixo que descrevem como matar facilmente o loop. Ele usa uma linguagem de script VB dinâmica para ajudar a manter o processo oculto em segundo plano durante a execução, mas ainda lhe dá o controle para usá-lo e matá-lo conforme necessário.

Script em lote

IF /I [%~N1]==[KillSwitch] TASKKILL /F /FI "WindowTitle eq ClearClip" & EXIT
IF NOT DEFINED MINIMIZED SET MINIMIZED=1 && START "" /MIN "%~F0" x && EXIT
@ECHO OFF
IF NOT [%~1]==[] GOTO :VBProcess

TITLE ClearClip
:LoopIt
ping -n 02 127.0.0.1 > nul

:WipeClip
cmd.exe /c echo off | clip
GOTO :LoopIt

:VBProcess
SET TempVBSFile=%temp%\~tmpVBSTemp.vbs
IF EXIST "%TempVBSFile%" DEL /F /Q "%TempVBSFile%"

ECHO Set WinScriptHost = CreateObject("WScript.Shell") >"%TempVBSFile%"
ECHO WinScriptHost.Run Chr(34) ^& "%~F0" ^& Chr(34), 0 >>"%TempVBSFile%"
ECHO Set WinScriptHost = Nothing                       >>"%TempVBSFile%"

CSCRIPT //nologo "%TempVBSFile%"
EXIT

Essentially this. . .

• Kills all processes with a title of "ClearClip" if the "KillSwitch" named file is passed to it as the first argument and then exits the script entirely (see Killing it with the Kill Switch)

• Starts [itself] the batch script again but minimized and with a passed dummy "x" value first argument

• Starts [itself] the batch script hidden with a dynamic VB script if the first argument passed to it is not null and then loops every 2 seconds clearing the clipboard

Para usá-lo

Para usá-lo ou ativar a funcionalidade para limpar a área de transferência a cada 2 segundos, basta clicar duas vezes ou executar o script em lote. Se você tiver problemas ou não funcionar como esperado, tente executá-lo como administrador com um simples clique com o botão direito do mouse em | Executar como administrador .

Matando com o Interruptor de Morte

1. Crie um arquivo com o nome KillSwitch.txt e coloque-o bem ao lado do script em lote que você salvou e execute para desativar a área de transferência

2. Arraste e solte o arquivo KillSwitch.txt name diretamente no script batch que você executou para desabilitar a área de transferência, e isso eliminará os processos de segundo plano ocultos que limpam a área de transferência e a área de transferência estará disponível novamente.

   

   

Maisrecursos

• Se
• Iniciar
• Ir para
• Título
• .Execute

• CScript

• CALL /?

  Substitution of batch parameters (%n) has been enhanced.  You can
  now use the following optional syntax:
  
      %~1         - expands %1 removing any surrounding quotes (")
      %~f1        - expands %1 to a fully qualified path name
      %~n1        - expands %1 to a file name only
  

• Limpar automaticamente sua área de transferência com ClipTTL