Gerador de senha de arquivo em lote que não fornece saída consistente

Question

eu tenho esse pedaço de código. É basicamente um gerador de senhas aleatório. Eu digite o comprimento da senha que eu quero dizer "10", então eu recebo uma senha aleatória gerada com 10 letras números e símbolos e é salvo em um arquivo txt. O problema acontece quando eu crio um segundo. Se eu quero novamente uma senha de comprimento "10", mas só me dá uma senha de dizer 3 ou 4. Depende. Alguma idéia de onde eu errei? qualquer ajuda é muito apreciada.

@Echo Off
mode con: cols=70 lines=25
:start
color 8a
echo ----------------------------------------------------------------------
echo --------                  Password Generator                   -------
echo ----------------------------------------------------------------------
echo.
echo.
Echo Hello %username%
set /P lengthnumberuser="What length do you want your password to be?:
cls
Setlocal EnableDelayedExpansion
Set _RNDLength=%lengthnumberuser%
Set _Alphanumeric=ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789%%$$@@**
Set _Str=%_Alphanumeric%987654321
:_LenLoop
IF NOT "%_Str:~18%"=="" SET _Str=%_Str:~9%& SET /A _Len+=9& GOTO :_LenLoop
SET _tmp=%_Str:~9,1%
SET /A _Len=_Len+_tmp
Set _count=0
SET _RndAlphaNum=
:_loop
Set /a _count+=1
SET _RND=%Random%
Set /A _RND=_RND%%%_Len%
SET _RndAlphaNum=!_RndAlphaNum!!_Alphanumeric:~%_RND%,1!
If !_count! lss %_RNDLength% goto _loop
echo.
echo.
echo.
cls
Echo Password is: !_RndAlphaNum!
set /p _detail=Please Record a description for this password:
echo.
echo %date%---%_detail%----!_RndAlphaNum! >> RandPass.txt
echo Password Saved with Details to RandPass.txt for future reference.
echo.
echo.
set /p _newpass= Would you like to create another password ?[y/n]:
cls

If /i "%_newpass%"== "y" GOTO :start else :end

:end

    

Answer 1

Eu não gosto de nomes de variáveis muito grandes, mas isso funciona:

@Echo Off
mode con: cols=70 lines=25
:start
color 8a
echo ----------------------------------------------------------------------
echo --------                  Password Generator                   -------
echo ----------------------------------------------------------------------
echo.
echo.
Echo Hello %username%
set /P len="What length do you want your password to be?:
cls
Setlocal EnableDelayedExpansion
Set "Chars=ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789$@*"
Set CharsCnt=65
Set "Pass="
For /L %%c in (1,1,%Len%) do (
  Set /a Pnt=!Random! %% CharsCnt
  Call Set "Pass=!Pass!%%Chars:~!Pnt!,1%%"
)
cls
Echo Password is: %Pass%
set /p _detail=Please Record a description for this password:
echo.
echo %date%---%_detail%----%Pass% >> RandPass.txt
echo Password Saved with Details to RandPass.txt for future reference.
echo.
echo.
set /p _newpass= Would you like to create another password ?[y/n]:
cls
If /i "%_newpass%"== "y" GOTO :start
:end

BTW: produzir várias linhas vazias e depois um cls não faz sentido para mim.