Como identifico linhas duplicadas em uma célula do Excel?

Question

Eu tenho um arquivo excel com milhares de linhas de informações de contato.

Eu preciso obter uma lista de todas as linhas que tenham nomes e sobrenomes duplicados.

Eu pude usar a formatação condicional para destacar as linhas que têm nomes duplicados, mas desejo obter uma lista de todas as duplicatas.

Como exemplo, minha lista é assim:

 First Name    Last    Email               Phone
 Tim           Berly   [email protected]       454-343-2123
 Tim           Berly   [email protected]     343-234-2343
 Mary          Berly   [email protected]       333-212-6996
 Jill          Brown   [email protected]    334-343-3443
 Mary          Red     [email protected]      444-454-4545
 Mary          Red     [email protected]   333-333-2222
 Bryan         Weasel  [email protected]    333-444-2235

Estou tentando fazer algo assim: Adicione uma nova coluna com valor = 1 se o primeiro nome e o sobrenome tiverem uma duplicata.

 Has Dup?     First Name    Last    Email               Phone
 1            Tim           Berly   [email protected]       454-343-2123
 1            Tim           Berly   [email protected]     343-234-2343
              Mary          Berly   [email protected]       333-212-6996
              Jill          Brown   [email protected]    334-343-3443
 1            Mary          Red     [email protected]      444-454-4545
 1            Mary          Red     [email protected]   333-333-2222
              Bryan         Weasel  [email protected]    333-444-2235

Obrigado pela sua ajuda.

    

Answer 1

Depois de adicionar a nova coluna, parece que o primeiro nome está em B1. Na A2, você pode adicionar qualquer uma das seguintes fórmulas,

=COUNTIFS(B:B, B2, C:C, C2)

Isso produzirá o número de ocorrências para o primeiro e o último nome (por exemplo, 1 para único, 2 ou mais para duplicatas).

Se você quiser uma fórmula mais complicada com resultados mais simples, talvez

=SIGN(COUNTIFS(B:B, B2, C:C, C2)-1)

Isso produzirá 0 para ocorrências únicas e 1 para qualquer duplicata, triplicata, etc. Isso pode ser expandido para uma declaração IF que deixa um string vazia para os singles.

=IF(COUNTIFS(B:B, B2, C:C, C2)>1, 1, "")

Este é o mais próximo dos resultados que você mostrou em sua amostra. Qualquer um desses deve identificar as duplicatas; isso só depende de como você deseja apresentar os resultados. A próxima (e última) opção mostrará apenas a segunda (ou terceira, etc) ocorrência.

=IF(SIGN(COUNTIFS(B$2:B2, B2, C$2:C2, C2)>1), 1, "")

Portanto, isso não identifica a primeira ocorrência de valores duplicados, mas identifica o segundo, terceiro, etc. com um 1 .

Preencha ou copie qualquer uma dessas fórmulas na coluna A, conforme necessário.

    

Answer 2

Se seus nomes estiverem classificados, você pode usar

=AND($B2=$B3, $C2=$C3)

começando na linha 3. Isso reportará TRUE para cada linha que tenha o mesmo nome e sobrenome da linha acima dela. Se você precisar do resultado mostrado (igual à linha acima ou abaixo ), defina A2 para

=AND($B2=$B3, $C2=$C3)

e A3 para

=OR(AND($B2=$B3, $C2=$C3), AND($B3=$B4, $C3=$C4))

(e arraste para baixo).

Se preferir 1 e 0 over TRUE e FALSE , inicie a fórmula com -- ; por exemplo,

=--OR(AND($B2=$B3, $C2=$C3), AND($B3=$B4, $C3=$C4))

Observe que essa resposta exige que seus dados sejam classificados pelo primeiro e último nome. Se você tiver

Tim           Berly   ...
Mary          Berly   ...
Tim           Berly   ...

isso não vai pegá-lo.