Localizando Valores Exclusivos em 3 Colunas

Question

Eu tenho 3 colunas no excel. Eu quero encontrar valores únicos nas colunas A, B e C.

Então:

1. procurando na coluna A, quero encontrar os valores exclusivos que não estão em B ou C.
2. procurando na coluna B, desejo encontrar valores exclusivos que não estejam na coluna A ou C.
3. procurando na coluna C, eu quero encontrar valores exclusivos que não estão na coluna A ou B.

Isso é o que eu coloco na coluna A

=IF(OR(MATCH(A3,$B$3:$B$631,0),(MATCH(A3,$C$3:$C$408,0))),"Match",A3) 

Isso é o que eu coloco na coluna B

=IF(OR(MATCH(B3,$A$3:$A$857,0),(MATCH(B3,$C$3:$C$408,0))),"Match",B3)

Isso é o que eu coloco na coluna C

=(IF(OR(MATCH(C3,$A$3:$A$857,0),(MATCH(C3,$B$3:$B$631,0))),"Match",C3)

Isso me dá valores duplicados nas três colunas que eu preciso que sejam exclusivos. Talvez eu esteja apenas fazendo isso muito complicado. Alguma idéia de como fazer isso?

O exemplo da tabela:

A   B   C
1   2   2
2   3   3
3   7   7
4   8   11
5   9   12
6   10  13

Neste caso, quero o número exclusivo em cada coluna. Portanto, para a coluna A, os valores únicos que não estão nas colunas B ou C são = a 1,4,5,6. Na coluna B os valores únicos, que não estão em A ou C, são = 8,9, 10. Na coluna C os valores únicos, que não estão em B ou C são = 11, 12, 13. Eu quero fazer um fórmula nas colunas D, E, F para estas três fórmulas.

A B C 1 2 2 2 3 3 3 7 7 4 8 11 5 9 12 6 10 13

Neste caso, quero o número exclusivo em cada coluna. Assim, para a coluna A, os valores unquie que não estão nas colunas B ou C são = a 1,4,5,6. Na coluna B os valores únicos, que não estão em A ou C, são = 8,9, 10. Na coluna C os valores únicos, que não estão em B ou C são = 11, 12, 13. Eu quero fazer um fórmula no columnc D, E, F para estas três fórmulas.

    

Answer 1

Você pode usar uma fórmula de matriz ^† como a seguinte em D1:

=IFERROR(INDEX($A$1:$A$6,SMALL(IF(ISERROR(MATCH($A$1:$A$6,$B$1:$B$6,0))*ISERROR(MATCH($A$1:$A$6,$C$1:$C$6,0)),ROW($A$1:$A$6)),ROW())),"")

As fórmulas nas outras colunas são semelhantes:

E1:

=IFERROR(INDEX($B$1:$B$6,SMALL(IF(ISERROR(MATCH($B$1:$B$6,$A$1:$A$6,0))*ISERROR(MATCH($B$1:$B$6,$C$1:$C$6,0)),ROW($B$1:$B$6)),ROW())),"")

F1:

=IFERROR(INDEX($C$1:$C$6,SMALL(IF(ISERROR(MATCH($C$1:$C$6,$A$1:$A$6,0))*ISERROR(MATCH($C$1:$C$6,$B$1:$B$6,0)),ROW($C$1:$C$6)),ROW())),"")

E na sua tabela de exemplo, recebo estes:

Se a sua fórmula começar em uma linha diferente da primeira, a fórmula precisará ser alterada um pouco porque ela usa ROW() , que depende da linha na qual a fórmula é inserida.

^† Nota: Para usar a fórmula, você deve pressionar e segurar Ctrl + Deslocar e pressionar Enter depois de inseri-lo.