VBA - comandos pop-up para preencher detalhes na planilha

Question

Eu posso encontrar com sucesso uma linha específica (por referência na coluna A), copiar a linha e colá-la abaixo do original.

Gostaria agora de poder solicitar informações para preencher determinadas células. Por exemplo.

1. Localize a linha 7, copie e cole na linha 8.
2. Em seguida, obtenha um pop-up para "Atualizar informações do trabalho" e insira-o na célula G8.

Esse padrão é sempre o mesmo, ou seja, atualiza a coluna G nas linhas coladas.

Qualquer ajuda é muito apreciada.

    

Answer 1

Como extensão da minha resposta à sua última pergunta, aqui está a macro novamente com a adição de uma solicitação de entrada de dados.

Sub CopyData()
    Dim res As String
    Dim cl As Range
    Dim sh As Worksheet

    ' operate on the active sheet
    Set sh = ActiveSheet

    ' ask for ID to find in column A
    res = InputBox("Enter ID to Find", "Copy Row")

    ' If no responce, exit
    If res = "" Then
        Exit Sub
    End If

    With sh
        ' Find first occurance
        Application.FindFormat.Clear
        Set cl = .Columns(1).Find(What:=res, _
            After:=.Cells(.Rows.Count, 1), _
            LookIn:=xlValues, _
            LookAt:=xlWhole, _
            SearchOrder:=xlByRows, _
            SearchDirection:=xlNext, _
            MatchCase:=True)

        If Not cl Is Nothing Then
            ' if found, select entire row
            Set cl = cl.EntireRow
            ' copy and insert paste data into next row
            cl.Copy
            cl.Offset(1, 0).Insert
            ' turn off copy highlight (moving border)
            Application.CutCopyMode = False

            ' Prompt for input
            res = InputBox("Enter some info for Column G", "Update job information")
            If res <> "" Then
                cl.Cells(2, 7) = res
            End If
        End If
    End With
End Sub