Como compactar arquivos separadamente (cada arquivo) em uma pasta usando o 7-zip?

Question

Estou usando o 7-zip no Windows 7 e tentando criar um lote para um arquivo zip automatizado em uma pasta.

Eu quero que cada um dos arquivos na pasta seja compactado separadamente.

Você pode procurar no meu código e sugerir como fazer melhor?

Consegui compactar tudo de uma pasta para outra, mas também preciso fazer separadamente cada arquivo:

@ECHO OFF
SET hr=%time:~0,2%
IF %hr% lss 10 SET hr=0%hr:~1,1%

Set TODAY=%date:~4,2%-%date:~7,2%-%date:~10,4%-%hr%%time:~3,2%%time:~6,2%%time:~9,2%

ECHO.

ECHO Compressing files and folders in C:\zipush drive and moving to C:\new
ECHO.
7za a -tzip "C:\new-drive-%TODAY%.zip" "C:\zipush*" -mx5
ECHO.

ECHO Delete the files in orginal folder 
DEL "C:\zipush\*.*"
PAUSE

    

Answer 1

Abaixo está o que você precisa fazer para completar um loop para zipar cada arquivo para o seu próprio arquivo zip com uma convenção de nomenclatura de <orignalfilename>.<extension>.zip , e depois excluir o original se o arquivo zip do arquivo anterior for bem-sucedido . Você pode alterar %%~NXA.zip para %%~NA.zip para não incluir a extensão do nome do arquivo original no novo arquivo zip, se necessário.

Você também deve garantir que o diretório de destino seja criado, caso ainda não exista, para que os comandos de arquivamento funcionem como esperado no loop, portanto, adicionei isso à lógica do script e também defini os diretórios de origem e de destino como variáveis em cima.

Também usei substituições em lote por meio do loop FOR para cuidar de nomes de arquivos e zip individuais. Consulte os Mais recursos de algum material didático sobre este tópico ( FOR /? ).

Exemplo de script

@ECHO OFF
SET hr=%time:~0,2%
IF %hr% lss 10 SET hr=0%hr:~1,1%

SET TODAY=%date:~4,2%-%date:~7,2%-%date:~10,4%-%hr%%time:~3,2%%time:~6,2%%time:~9,2%

SET SrcDir=C:\zipush
SET DestDir=C:\new-drive-%TODAY%
IF NOT EXIST "%DestDir%" MD "%DestDir%"

ECHO.

ECHO Compressing files and folders in C:\zipush drive and moving to C:\new
ECHO.

ECHO Compressing files and folders in C:\zipush drive and moving to C:\new and then delete from C:\zipush
ECHO.
FOR %%A IN ("%SrcDir%\*.*") DO 7za a -tzip "%DestDir%\%%~NXA.zip" "%%~A" -mx5 && DEL /Q /F "%%~A"
ECHO.
PAUSE

Mais recursos

• PARA
• Execução condicional

• MD

• FOR /? no prompt de comando

  In addition, substitution of FOR variable references has been enhanced.
  You can now use the following optional syntax:
  
  %~I         - expands %I removing any surrounding quotes (")
  %~fI        - expands %I to a fully qualified path name
  %~dI        - expands %I to a drive letter only
  %~pI        - expands %I to a path only
  %~nI        - expands %I to a file name only
  %~xI        - expands %I to a file extension only
  %~sI        - expanded path contains short names only
  %~aI        - expands %I to file attributes of file
  %~tI        - expands %I to date/time of file
  %~zI        - expands %I to size of file
  %~$PATH:I   - searches the directories listed in the PATH
                 environment variable and expands %I to the
                 fully qualified name of the first one found.
                 If the environment variable name is not
                 defined or the file is not found by the
                 search, then this modifier expands to the
                 empty string