Como eu uso a função AND e a função MATCH juntas para obter algo que não é “Não” e não foi retornado anteriormente

Question

Eu tenho os seguintes dados e preciso retornar todos os valores que não são "Não". Ou seja, quero criar, em outra coluna, uma lista de todos os valores da coluna E que não são "Não". Nunca haverá duplicatas nos dados originais (diferente das repetições múltiplas de "Não").

    E 
5   No  
6   No  
7   IC3  
8   No   
9   J1   
10  J2
11  J3
12  No

No minuto em que eu sou, posso obter o primeiro valor diferente de "Não". Eu estou tentando usar a função CORRESP para retornar valores < > "Não" E < > [valores em células anteriores].

Eu tenho a seguinte fórmula na célula L12

{=INDEX($E$5:$E$12,AND(MATCH(TRUE,$E$5:$E$12<>"No"),MATCH(TRUE,$E$5:$E$12<>$L$5:L11)),0)}

Alguém tem alguma ideia?

    

Answer 1

Com dados de A1 até A14 , em B1 digite:

=IF(A1="No","",A1)

e copie para baixo. Então, em C1 , insira a Fórmula da Matriz :

=IFERROR(INDEX($B$1:$B$14,SMALL((IF(LEN($B$1:$B$14),ROW(INDIRECT("1:"&ROWS($B$1:$B$14))))),ROW(A1)),1),"")

e copie para baixo. Por exemplo:

    

Answer 2

Ponha esta fórmula, usada para determinar o número esperado de devoluções, por ex. L1:

=COUNTIF($E$5:$E$12,"<>No")

Então, esta fórmula na sua primeira célula de escolha:

=IF(ROWS($1:1)>$L$1,"",INDEX($E:$E,AGGREGATE(15,6,ROW(E$5:E$12)/(E$5:E$12<>"No"),ROWS($1:1))))

(Você precisará de uma pequena modificação se estiver usando uma versão anterior ao 2010 do Excel.)

Copie esta fórmula (embora não a de L1) até começar a obter os resultados em branco.

Atenciosamente

    

Answer 3

Aqui está uma que não requer uma coluna auxiliar. Supondo que seus dados começam em A1:

=IFERROR(INDEX(A$1:A$14,SMALL(IF(A$1:A$14<>"No",ROW(A$1:A$14)-MIN(ROW(A$1:A$14))+1,""),ROW())),"")

Confirme como uma fórmula de matriz com ctrl + shift + enter e autofill down. O modo como está escrito tem que começar na primeira linha, mas você pode ajustar o último ROW () para começar em outro lugar se precisar.