Como retornar o texto à esquerda da quebra de linha

Question

Eu tenho uma planilha do Excel, que contém uma célula com este conteúdo:

Text1: "abc" linebreak1  
....  
Text31: "mno" linebreak31  

Text 32: ... linebreak32  
...  
Text50: "xyz" linebreak50  

Não, eu vou ler "mno", que é antes da quebra de linha 31 na célula do excel. Eu abri meu arquivo excel com editor hexadecimal e notei a linha de quebra após "o" na linha "Text31"
e usou a seguinte fórmula:

MID(CELL,FIND("Text31: ",CELL),FIND("Text31: ",CELL)-
FIND(CHAR(13)&CHAR(10),CELL))

mas realmente não funcionou. Ele retornou as duas linhas seguintes (linha em branco e "Text32:" - linha).

Eu não sei exatamente como posso recuperar o texto deixado na linha 31. Como posso obter este texto?

    

Answer 1

Se você está apenas tentando extrair mno , isso deve funcionar. Observe que B3 é o texto.

EDITAR Ligeiro erro na fórmula, aqui está a correção:

=LEFT(MID(B3,FIND("Text31: """,B3)+LEN("Text31: """),LEN(B3)-FIND("Text31: """,B3)-LEN("Text31: """)),FIND("""",MID(B3,FIND("Text31: """,B3)+LEN("Text31: """),LEN(B3)-FIND("Text31: """,B3)-LEN("Text31: """)))-1)

Editar 2: Desde que é um pouco confuso, aqui está como eu cheguei com a fórmula. Eu quebrei tudo em etapas / peças e coloquei em suas próprias células. Continuei isso até que eu tivesse o resultado correto. Eu fui capaz de construir o fromula completo a partir disso.

Veja como eu resolvi isso, e você deve poder copiar e colar diretamente no Excel. Coloque o texto original em B3 e cole o seguinte abaixo (em B4-B11):

="Text31: """
=FIND(B4,B3)
=LEN(B4)
=LEN(B3)-B5-B6
=MID(B3,B5+B6,B7)
=FIND("""",B8)
=LEFT(B8,B9-1)

Aqui estão minhas descrições que você pode colar no A4-A11 para ajudá-lo a descobrir o que diabos você está olhando:

Text Prior to 'mno' : 
Start position of Prior Text:
Length of Prior Text:
Length of Original Text - Prior Text - Length of Prior Text:
Remaining Text:
Distance to next ":
Result: