Como forçar o Excel a tratar datas em CSV como texto em uma macro

Question

Eu tenho uma macro que permite ao usuário selecionar um arquivo CSV e depois manipulá-lo. No entanto, ele trata células que contêm coisas como 1/2/12 como uma data. Eu preciso manter essas strings como texto, não datas.

Eu sei que posso fazer isso 1) inicie uma nova planilha 2) importe o CSV em vez de abri-lo. Defina a coluna com as datas para "texto" e termine.

A pergunta é: como posso interromper o Data > Importe para que o usuário possa selecionar o arquivo. Depois disso, a macro deve continuar a definir o formato das colunas, concluir a importação e executar as manipulações de dados.

Editar: Aqui está o código relevante da macro como está:

ChDir "C:\RoomTimerData\"

MyFile = Application.GetOpenFilename("Comma Separated Values (.csv),.csv")

Workbooks.Open fileName:=MyFile

    

Answer 1

Normalmente, um deve selecionar o tipo de dados para cada coluna importada como etapa 3 de 3 da caixa de diálogo de importação de texto. Para evitar erros de formatação, use texto como formato e você é bom.

No entanto, parece que você usa uma macro VBA para importar seus arquivos CSV. Então eu gravei uma importação de texto incorrupta:

With ActiveSheet.QueryTables.Add(Connection:= _
    "TEXT;C:\test.csv", Destination:=Range("$A$1"))
    .Name = "test_1"
    .FieldNames = True
    .RowNumbers = False
    .FillAdjacentFormulas = False
    .PreserveFormatting = True
    .RefreshOnFileOpen = False
    .RefreshStyle = xlInsertDeleteCells
    .SavePassword = False
    .SaveData = True
    .AdjustColumnWidth = True
    .RefreshPeriod = 0
    .TextFilePromptOnRefresh = False
    .TextFilePlatform = 850
    .TextFileStartRow = 1
    .TextFileParseType = xlDelimited
    .TextFileTextQualifier = xlTextQualifierDoubleQuote
    .TextFileConsecutiveDelimiter = False
    .TextFileTabDelimiter = False
    .TextFileSemicolonDelimiter = True
    .TextFileCommaDelimiter = False
    .TextFileSpaceDelimiter = False
    .TextFileColumnDataTypes = Array(2, 1) 'THIS IS THE MAGIC LINE!
    .TextFileTrailingMinusNumbers = True
    .Refresh BackgroundQuery:=False
End With

Além disso, veja este exemplo da ajuda do excel para TextFileColumnDataTypes :

Set shFirstQtr = Workbooks(1).Worksheets(1) 
Set qtQtrResults = shFirstQtr.QueryTables _
        .Add(Connection := "TEXT;C:\My Documents980331.txt", _
        Destination := shFirstQtr.Cells(1, 1))
With qtQtrResults
    .TextFileParseType = xlFixedWidth
    .TextFileFixedColumnWidths = Array(5, 4)
    .TextFileColumnDataTypes = _
        Array(xlTextFormat, xlSkipColumn, xlGeneralFormat)
    .Refresh
End With

Estes são os formatos que você pode usar:

• xlGeneralFormat
• xlTextFormat
• xlSkipColumn
• xlDMYFormat
• xlDYMFormat
• xlEMDFormat
• xlMDYFormat
• xlMYDFormat
• xlYDMFormat
• xlYMDFormat