carbon emacs yank resulta em imagens

Question

Na instalação padrão do Carbon Emacs no OS X, copiar um arquivo do Finder e puxá-lo para o emacs resulta apenas no ícone que está sendo exibido.

Como eu gostaria de personalizá-lo para que ele forneça o caminho do arquivo?

    

Answer 1

Consegui desabilitar todos os arranques de imagens (arrastar e soltar ainda funciona se eu realmente quiser uma imagem lá) sobrescrevendo uma função declarada no mac-win.el (arquivo não compilado não incluído na instalação padrão.)

no meu .emacs:

;; prohibit pasting of TIFFs
(defun x-selection-value (type)
  (let ((data-types '(public.file-url
                       public.utf16-plain-text
                       com.apple.traditional-mac-plain-text))
    text)
    (while (and (null text) data-types)
      (setq text (condition-case nil
             (x-get-selection type (car data-types))
           (error nil)))
      (setq data-types (cdr data-types)))
    (if text
    (remove-text-properties 0 (length text) '(foreign-selection nil) text))
    text))

original foi:

(defun x-selection-value (type)
  (let ((data-types '(public.utf16-plain-text
              com.apple.traditional-mac-plain-text
              public.file-url))
    text tiff-image)
    (while (and (null text) data-types)
      (setq text (condition-case nil
             (x-get-selection type (car data-types))
           (error nil)))
      (setq data-types (cdr data-types)))
    (if text
    (remove-text-properties 0 (length text) '(foreign-selection nil) text))
    (setq tiff-image (condition-case nil
             (x-get-selection type 'public.tiff)
               (error nil)))
    (when tiff-image
      (remove-text-properties 0 (length tiff-image)
                  '(foreign-selection nil) tiff-image)
      (setq text (mac-TIFF-to-string tiff-image text)))
    text))