Fórmula para formatar o valor de minutos em “N horas, M minutos”

Question

Estou me referindo a essa questão respectivamente para esta editada resposta . Há uma coluna com períodos de tempo em minutos. O período de três horas e dois minutos seria 182 . Como formatar condicionalmente as células usando uma fórmula para obter os seguintes resultados?

0 → 0 minutes

1 → 1 minute

2 → 2 minutes

60 → 1 hour

120 → 2 hours

181 → 3 hours, 1 minute

63 → 1 hour, 3 minutes

Preciso fazer alguma divisão (arredondada) e algum cálculo de módulo? Ou há uma função interna para coisas assim?

    

Answer 1

=IF(A1=0,"0 minutes",IF(A1>=60,FLOOR(A1/60,1) & " hour" & IF(A1>=120,"s",""),"") & IF(MOD(A1,60)>0,IF(A1>=60,", ","") & MOD(A1,60) & " minute" & IF(MOD(A1,60)>1,"s",""),""))

De acordo com os comentários você está usando o Excel alemão, que usa ponto-e-vírgula para separar parâmetros de função, então substitua as vírgulas por ponto e vírgula:

=IF(A1=0;"0 minutes";IF(A1>=60;FLOOR(A1/60;1) & " hour" & IF(A1>=120;"s";"");"") & IF(MOD(A1;60)>0;IF(A1>=60;", ";"") & MOD(A1;60) & " minute" & IF(MOD(A1;60)>1;"s";"");""))

(Nota: ainda há uma vírgula lá porque está na string de saída.)

0      0 minutes
1      1 minute
2      2 minutes
59     59 minutes
60     1 hour
61     1 hour, 1 minute
62     1 hour, 2 minutes
119    1 hour, 59 minutes
120    2 hours
121    2 hours, 1 minute
122    2 hours, 2 minutes
179    2 hours, 59 minutes
180    3 hours
181    3 hours, 1 minute
182    3 hours, 2 minutes
1439   23 hours, 59 minutes
1440   24 hours

    

Answer 2

Suponha que seus dados estejam na coluna A. Escreva essa fórmula em C2 e preencha-a para traduzir os minutos para os dias fracionários (que é como o Excel armazena os tempos):

=A2/1440

Observação , Como você pode encontrar acima nos comentários também, para converter os minutos decimais em formato de hora, você pode aplicar esta fórmula 24*60 , que dá 1440 .

Com os minutos convertidos para o formulário no qual o Excel manipula o tempo, você pode simplesmente usar a formatação de hora personalizada para exibi-la. Selecione o intervalo de dados e aplique este formato de célula:

h "hours, " m "minutes"

Observe que o Excel tratará os horários como horas apenas até o limite de um dia inteiro, portanto, isso funcionará, desde que seus horários não sejam superiores a 24 horas.

Ou, você pode usar as funções HOUR e MINUTE para extrair os componentes do tempo. Em D2 você pode usar:

=HOUR(C2)&" hours, "&MINUTE(C2)&" minutes "

Você começa,

Novamente,issoélimitadoàpartedoseutempoqueémenorqueumdia.Sevocêpudertermaisdeumdia,adicioneacontagemdedias:

=INT(C2)&" days, "&HOUR(C2)&" hours, "&MINUTE(C2)&" minutes "

Agora você começa,