Existe um atalho de teclado para “Salvar na sua biblioteca” no aplicativo de desktop do Spotify?

Question

Save to Your Library é uma ótima maneira de salvar músicas favoritas e reproduzi-las como uma playlist mais tarde. Também é legal fazer com que Your Library > Songs esteja disponível off-line no celular. Então você nunca está sem algo bom para ouvir.

Enquanto ouço no meu computador de mesa, gostaria de adicionar a faixa atual sem esforço à minha biblioteca.
Existe um atalho de teclado para que isso aconteça?

Para referência, havia um recurso semelhante chamado "Com estrela" com uma pergunta sobre superusuário desatualizada aqui .

    

Answer 1

Nenhum atalho de teclado, e muito menos Save to Your Library , está embutido nos aplicativos da área de trabalho do Spotify e provavelmente nunca será. Em dezembro de 2016, eles marcaram o pedido (originalmente de 2012) como "Not Right Now".

Para usuários do macOS, não conheço uma solução.

Para usuários do Windows AutoHotkey é bastante viável.

Aqui está um script AutoHotkey que funciona a partir de 10-30-2017.

; Control+Shift+Win+F1
^+#F1:: SendInput {Media_Play_Pause}

; Control+Shift+Win+F2
^+#F2:: SendInput {Media_Prev}

; Control+Shift+Win+F3
^+#F3:: SendInput {Media_Next}

; Control+Shift+Win+F4
^+#F4:: SaveSongToSpotifyLibrary()


SaveSongToSpotifyLibrary() {
  spotify := "ahk_exe spotify.exe"
  if WinExist(spotify) {
    ; Store starting window ID and mouse position.
    MouseGetPos x, y, startingWinId

    ; Activate Spotify.
    WinActivate %spotify%
    WinWaitActive %spotify%

    saveToYourLibraryIcon = %A_WorkingDir%\apps\SpotifyController\SaveToYourLibraryIcon.png
    ImageSearch FoundX, FoundY, 0, 0, A_ScreenWidth, A_ScreenHeight, %saveToYourLibraryIcon%
    if (ErrorLevel = 0) {
      Click %FoundX%, %FoundY%

    } else if (ErrorLevel = 2) {
      MsgBox % "Problem conducting image search. Is the saveToYourLibraryIcon in the correct location?"

    } else if (ErrorLevel = 1) {
      MsgBox % "Unable to save song. Can't find the Add button."
    }

    ; Restore original window and mouse position.
    WinActivate ahk_id %startingWinId%
    MouseMove %x%, %y%
  }
}

Instruções

• Se você nunca criou um script antes, consulte o Tutorial para iniciantes .

• Isso usa a função ImageSearch . Criei a imagem para encontrar tirando uma captura de tela do botão de adição no canto inferior esquerdo do aplicativo Spotify.
  Você pode criar um você mesmo ou baixar este aqui.
  

• Nomeie-o com SaveToYourLibraryIcon.png e coloque-o no mesmo diretório do seu script.

• É isso. Pressione Ctrl+Shift+Win+F4 ( altere isso para o que você quiser ) e a música ativa será adicionada à sua biblioteca!