Vim; Executando outro aplicativo por: MyCommand

Question

Eu quero executar "go install" no diretório atual (onde o documento atualmente aberto reside) com um comando (Like: GoInstall).

Como posso fazer isso?

Nota: também quero ver a saída desse comando.

Eu adicionei command Goin execute "go install" a _gvimrc e _vimrc (eu estou no Windows), mas ele não funciona - diz que não é um comando de editor - ou dá E488 e não tenho certeza se está sendo executado no diretório atual. / p>

ATUALIZAÇÃO:

Depois de algumas dificuldades em conhecer o Vim melhor e principalmente pesquisando no Google, acabei com esse arquivo _gvimrc que funciona perfeitamente (pelo menos para mim). Ele adiciona três comandos Gon, Gob e Gor para executar go install , go build e go run current_file.go e mostra o resultado em outro documento (buffer) no Vim. Espero que ajude alguém que é iniciante do Vim:

set guifont=Lucida_Console:h11
colorscheme dejavu
set tabstop=4

filetype plugin on
filetype plugin indent on
syntax on

" causes vim opens maximized in windows (@least)
au GUIEnter * simalt ~x

set autochdir
set number

" this made my vim life (as a begginer at least) much happier!
" thanks to @ http://vim.wikia.com/wiki/Display_output_of_shell_commands_in_new_window bottom of the page
function! s:ExecuteInShell(command, bang)
    let _ = a:bang != '' ? s:_ : a:command == '' ? '' : join(map(split(a:command), 'expand(v:val)'))

    if (_ != '')
        let s:_ = _
        let bufnr = bufnr('%')
        let winnr = bufwinnr('^' . _ . '$')
        silent! execute  winnr < 0 ? 'belowright new ' . fnameescape(_) : winnr . 'wincmd w'
        setlocal buftype=nowrite bufhidden=wipe nobuflisted noswapfile wrap number
        silent! :%d
        let message = 'Execute ' . _ . '...'
        call append(0, message)
        echo message
        silent! 2d | resize 1 | redraw
        silent! execute 'silent! %!'. _
        silent! execute 'resize ' . line('$')
        silent! execute 'syntax on'
        silent! execute 'autocmd BufUnload <buffer> execute bufwinnr(' . bufnr . ') . ''wincmd w'''
        silent! execute 'autocmd BufEnter <buffer> execute ''resize '' .  line(''$'')'
        silent! execute 'nnoremap <silent> <buffer> <CR> :call <SID>ExecuteInShell(''' . _ . ''', '''')<CR>'
        silent! execute 'nnoremap <silent> <buffer> <LocalLeader>r :call <SID>ExecuteInShell(''' . _ . ''', '''')<CR>'
        silent! execute 'nnoremap <silent> <buffer> <LocalLeader>g :execute bufwinnr(' . bufnr . ') . ''wincmd w''<CR>'
        nnoremap <silent> <buffer> <C-W>_ :execute 'resize ' . line('$')<CR>
        silent! syntax on
    endif
endfunction

command! -complete=shellcmd -nargs=* -bang Shell call s:ExecuteInShell(<q-args>, '<bang>')
cabbrev shell Shell

command! -complete=shellcmd -nargs=* -bang Gor call s:ExecuteInShell('go run %', '<bang>')
command! -complete=shellcmd -nargs=* -bang Gon call s:ExecuteInShell('go install', '<bang>')
command! -complete=shellcmd -nargs=* -bang Gob call s:ExecuteInShell('go build', '<bang>')

:map <F5> :Gor<CR>
:map <F6> :Gob<CR>
:map <F7> :Gon<CR>

Nota: Você precisa configurar pelo menos GOROOT e GOPATH env-vars em seu sistema.

    

Answer 1

:execute é para comandos ex-internos, você quer que o comando :! execute um comando externo :

:!go install

Parece que a opção 'makeprg' seria benéfica também. A compilação é uma tarefa tão frequente que o vi / Vim possui um mecanismo de trigger embutido. Se você

:set makeprg=go

você pode acionar a compilação com :make install .

Para mudar para o diretório atual, use

:cd %:h

ou (sempre para isso automaticamente):

:set autochdir