Obtendo um intervalo de medianas no Excel, a partir de uma única coluna de dados?

Question

Eu tenho um grande número de linhas de dados na coluna 'A' no Excel.

O que eu gostaria de fazer é obter a mediana em intervalos de 8 respostas ( =MEDIAN(A1:A8) , depois a mediana das próximas 8 respostas =MEDIAN(A9:A16 e assim por diante). Como posso fazer isso sem alterar manualmente a fórmula?

O conselho seria muito apreciado! :)

    

Answer 1

Duas abordagens possíveis

1.Crie a fórmula como um valor de texto e, em seguida, converta para uma fórmula real, por ex. Ponha esta fórmula em B1 e copie o quanto precisar

="=MEDIAN(A"&ROWS(B$1:B1)*8-7&":A"&ROWS(B$1:B1)*8&")"

Agora converta para texto fazendo isso

Copie a coluna B e clique com o botão direito do mouse e use Colar especial > Valores > OK

Agora converta para uma fórmula fazendo isso

Selecione a coluna B e use Dados > Texto para colunas > Concluir

2.Use esta fórmula em B1 copiada para baixo

=MEDIAN(OFFSET(A$1,ROWS(B$1:B1)*8-8,0,8))

O primeiro método é um pouco mais complexo, mas você acaba com as fórmulas MEDIANAS exatas que você queria. A segunda abordagem é mais simples e dá os resultados corretos, mas não é óbvio, olhando para as fórmulas, o que cada uma está fazendo

    

Answer 2

Você pode usar a seguinte fórmula (em B1) e preencher:

=MEDIAN(INDIRECT("A"&(ROW()-1)*8+1&":A"&ROW()*8))

    

Answer 3

Abaixo da fórmula é o caminho mais longo de representação: -

=IF(ISERROR(MEDIAN(INDIRECT("A"&IF(ROW(A1)=1,ROW(A1),ROW(A1)+(7*(ROW(A1)-1)))):INDIRECT("A"&IF(ROW(A8)=8,ROW(A8),ROW(A8)+(7*(ROW(A1)-1)))))),"Not Applicable",MEDIAN(INDIRECT("A"&IF(ROW(A1)=1,ROW(A1),ROW(A1)+(7*(ROW(A1)-1)))):INDIRECT("A"&IF(ROW(A8)=8,ROW(A8),ROW(A8)+(7*(ROW(A1)-1))))))

Mas, felizmente, barry obteve a menor representação.