bat file to tick ar untick usando o proxy no PC

Question

É nessa hora do dia, saindo do escritório e sentado em casa, ligue o seu laptop, você precisa desativar usando o proxy no nível do PC no painel de controle > opções de internet > conexões > proxy off ... na manhã seguinte, a mesma coisa no escritório, mais uma vez vá tudo isso para ativá-lo novamente ... em seguida, encontrar o inetcpl.cpl de Executar para certificar-se de chegar a esse diálogo mais fácil tick / un-tick e dizer OK

é irritante, eu queria ter um arquivo bat ou uma chave reg para fazer esse clique em vez de fazê-lo o tempo todo! nada funcionou depois de muitas pesquisas e tentando muitos cenários ..

Eu sei que os navegadores têm substitutos de ativação / desativação de proxy e funcionam bem no Chrome, mas, para que tudo funcione, é necessário fazer isso a partir das opções da Internet, para que ele seja no nível do PC ...

Qualquer ideia de trabalho é bem-vinda

Obrigado

    

Answer 1

Sem palavras: -)

:: EnableProxy
@Echo off
set "Key=HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings"
Set "Val=ProxyEnable"
Set "Typ=REG_DWORD"
Reg add "%Key%" /v %Val% /t %Typ% /d "0x1" /f

:: Disable Proxy
@Echo off
set "Key=HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings"
Set "Val=ProxyEnable"
Set "Typ=REG_DWORD"
Reg add "%Key%" /v %Val% /t %Typ% /d "0x0" /f

:: ToggleProxy.cmd
@Echo off
set "Key=HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings"
Set "Val=ProxyEnable"
Set "Typ=REG_DWORD"
for /f "tokens=3" %%R in (
  'Reg Query "%Key%" /v %Val% ^|find /i "%Val%"'
) do if "%%~R" equ "0x0" (
   Reg add "%Key%" /v %Val% /t %Typ% /d "0x1" /f
) else (
   Reg add "%Key%" /v %Val% /t %Typ% /d "0x0" /f
)

Eu escrevi um semelhante no StackOverflow para alternar entre dois proxies diferentes .