Envie e-mails em massa ao receber um e-mail de um endereço específico no Outlook ou no Thunderbird

Question

Eu quero um filtro ou uma regra que me permita enviar emails em massa para cerca de 200 destinatários quando um email for recebido de um endereço específico. Por exemplo, quando o cliente de e-mail recebe um e-mail de [email protected] , quero que ele reenvie o e-mail para todas as pessoas no meu catálogo de endereços.

Eu tentei estabelecer regras nos clientes de e-mail Outlook e Thunderbird, mas a única opção que eu tenho é "Encaminhar", não "Reenviar" ou "Enviar" o e-mail. Há um problema adicional em que todos os destinatários apareçam na lista de endereços. Quero que todos os destinatários sejam bcc.

Existe alguma maneira de fazer isso?

    

Answer 1

Você pode criar uma regra para encaminhar para uma lista de distribuição com bcc.

Editar 2015 02 23

Embora o acima seja tecnicamente verdadeiro. Não é tão simples quanto eu pensava. Não há opção de Cco na caixa de diálogo para endereços ao encaminhar por regra. Minha versão é de 2010.

Você pode definir um Cco em uma regra com uma opção de script em vez de usar a caixa de diálogo.

Option Explicit

Sub Forward_BCC_DL(item As Object)

Dim newForward As MailItem
Dim myRecipient As Recipient

If item.Class = olMail Then

    Set newForward = item.Forward

    Set myRecipient = newForward.Recipients.Add("Name of Distribution List with the quotes")
    myRecipient.Type = olBCC

    newForward.Recipients.ResolveAll
    newForward.Display  ' Comment out with a leading apostrophe once tested
    'newForward.Send    ' Remove leading apostrophe once tested

End If

ExitRoutine:
    Set newForward = Nothing
    Set myRecipient = Nothing

End Sub

Private Sub Forward_BCC_DL_Test()
' To test
'  open a message then run this code
Dim curritem As Object
Set curritem = ActiveInspector.currentItem
Forward_BCC_DL curritem
End Sub

Se você não estiver familiarizado com o VBA, isso será útil.

Introdução ao VBA no Outlook 2010

Como usar o editor VBA do Outlook

Editar 2015 02 23 - Fim

Editar 2015 02 24

Provavelmente, é melhor criar uma lista de distribuição como usada acima, mas isso recuperará lentamente todos os contatos.

Option Explicit

Sub Forward_BCC_All(mail As MailItem)

    Dim ContactsFolder As folder
    Dim Contact As Object
    Dim objMail As MailItem
    'Dim j As Long
    Dim objRecip As Recipient

    Set ContactsFolder = Session.GetDefaultFolder(olFolderContacts)

    Set objMail = mail.Forward
    'j = 0

    For Each Contact In ContactsFolder.Items

        'j = j + 1

        With objMail
            'Debug.Print j & ": " & Contact
            Set objRecip = .Recipients.Add(Contact)
            objRecip.Type = olBCC
        End With

    Next

    'Debug.Print "Resolving contacts slowly"

    objMail.Recipients.ResolveAll
    objMail.Display

ExitRoutine:
    Set objMail = Nothing
    Set ContactsFolder = Nothing
    Set Contact = Nothing

End Sub

Private Sub Forward_BCC_All_test()
Dim currItem As MailItem
Set currItem = ActiveInspector.currentItem
Forward_BCC_All currItem
End Sub

Editar 2015 02 24 - Fim