Como especificar a grade em termos de células, não de distâncias?

Question

É possível especificar uma grade em termos de número de linhas de grade, em vez de espaçamento (no PowerPoint 2016)? Eu quero ter uma grade de 2x3 para me ajudar a projetar minha apresentação, mas só posso encontrar uma maneira de especificar a grade em termos de distância entre linhas.

As configurações que encontrei:

    

Answer 1

Aqui está um exemplo de código de uma página no site do PowerPoint FAQ que eu mantenho:

Trabalhando com guias no PPT 2013 e posterior link

Se você não está acostumado a trabalhar com o VBA, há um link para um tutorial simples na parte inferior da página.

Isso permite que você adicione guias horiz / vert praticamente onde quiser:

Sub AddGuides()

    Dim HGuides As String
    Dim VGuides As String
    Dim x As Long
    Dim aGuideArray() As String

    ' Edit these to indicate where you'd like to put guides:
    ' Values are in points, 72 points to the inch
    ' Separate each value from the next with a pipe | character

    ' Horizontal guide positions:
    HGuides = "72|144|256.5"
    ' Vertical guide positions:
    VGuides = "10|20|30|40|50|60|70|80|90|100"

    With ActivePresentation
        ' nb ppHorizonatalGuide = 1; ppVerticalGuide = 2
        ' nb to add guides to master rather than slides,
        '   use .SlideMaster.Guides.Add below
        '   in place of .Guides.Add

        ' First add the horizontal guides
        aGuideArray = Split(HGuides, "|")
        For x = LBound(aGuideArray) To UBound(aGuideArray)
            .Guides.Add ppHorizontalGuide, CSng(aGuideArray(x))
        Next

        ' and now the vertical guides
        aGuideArray = Split(VGuides, "|")
        For x = LBound(aGuideArray) To UBound(aGuideArray)
            .Guides.Add ppVerticalGuide, CSng(aGuideArray(x))
        Next

    End With

End Sub